Merge pull request #90 from arduino-libraries/Esquirio/re_frame_codes

Esquirio/re frame codes

Author: aentinger

examples/Platform_Tutorials/lessons/03-important-programming-concepts/Braccio_moving_range_angles/Braccio_moving_range_angles.ino

@@ -0,0 +1,117 @@
+/**************************************************************************************
+ * INCLUDE
+ **************************************************************************************/
+
+#include <Braccio++.h>
+
+/**************************************************************************************
+ * DEFINES
+ **************************************************************************************/
+
+#define BUTTON_SELECT  3
+#define BUTTON_ENTER   6
+#define TIME_DELAY     2000
+
+/**************************************************************************************
+ * CONSTANTS
+ **************************************************************************************/
+
+static float const HOME_POS[6] = {157.5, 157.5, 157.5, 157.5, 157.5, 90.0};
+
+/**************************************************************************************
+ * GLOBAL VARIABLES
+ **************************************************************************************/
+
+static auto gripper    = Braccio.get(1);
+static auto wristRoll  = Braccio.get(2);
+static auto wristPitch = Braccio.get(3);
+static auto elbow      = Braccio.get(4);
+static auto shoulder   = Braccio.get(5);
+static auto base       = Braccio.get(6);
+
+float angles[6];
+
+/**************************************************************************************
+ * SETUP/LOOP
+ **************************************************************************************/
+
+void setup() {
+  if (Braccio.begin())
+  {
+    /* Warning: keep a safe distance from the robot and watch out for the robot's
+       movement. It could be speedy and hit someone. */
+    /* Move to home position. */
+    Braccio.moveTo(HOME_POS[0], HOME_POS[1], HOME_POS[2], HOME_POS[3], HOME_POS[4], HOME_POS[5]);
+    delay(TIME_DELAY);
+  }
+}
+
+void loop() {
+  int pressedKey = Braccio.getKey();
+
+  if (pressedKey == BUTTON_ENTER)
+  {
+    // Pinch movement
+    gripper.move().to(230.0f);         delay(TIME_DELAY);
+    gripper.move().to(HOME_POS[0]);    delay(TIME_DELAY);
+
+    // // Wrist Roll movement
+    wristRoll.move().to(0.0f);          delay(TIME_DELAY);
+    wristRoll.move().to(HOME_POS[1]);   delay(TIME_DELAY);
+    wristRoll.move().to(315.0f);        delay(TIME_DELAY);
+    wristRoll.move().to(HOME_POS[1]);   delay(TIME_DELAY);
+
+    // // Wrist Pitch movement
+    wristPitch.move().to(70.0f);       delay(TIME_DELAY);
+    wristPitch.move().to(HOME_POS[2]); delay(TIME_DELAY);
+    wristPitch.move().to(260.0f);      delay(TIME_DELAY);
+    wristPitch.move().to(HOME_POS[2]); delay(TIME_DELAY);
+
+    // Elbow movement
+    for(float i=HOME_POS[3]; i >= 70.0; i-=5)
+        { elbow.move().to(i);          delay(TIME_DELAY/2000); }
+    elbow.move().to(HOME_POS[3]);      delay(TIME_DELAY);
+    for(float i=HOME_POS[3]; i <= 260.0; i+=5)
+        { elbow.move().to(i);          delay(TIME_DELAY/2000); }
+    elbow.move().to(HOME_POS[3]);      delay(TIME_DELAY);
+
+    // Shoulder movement
+    shoulder.move().to(120.0f);       delay(TIME_DELAY/2);
+    shoulder.move().to(90.0f);        delay(TIME_DELAY/2);
+    shoulder.move().to(120.0f);       delay(TIME_DELAY/2);
+    shoulder.move().to(HOME_POS[4]);  delay(TIME_DELAY);
+    shoulder.move().to(200.0f);       delay(TIME_DELAY/2);
+    shoulder.move().to(230.0f);       delay(TIME_DELAY/2);
+    shoulder.move().to(200.0f);       delay(TIME_DELAY/2);
+    shoulder.move().to(HOME_POS[4]);  delay(TIME_DELAY);
+
+    // Base movement
+    base.move().to(0.0f);              delay(TIME_DELAY);
+    base.move().to(HOME_POS[5]);       delay(TIME_DELAY);
+    base.move().to(315.0f);            delay(TIME_DELAY);
+    base.move().to(HOME_POS[5]);       delay(TIME_DELAY);
+
+    while(pressedKey == BUTTON_ENTER) { pressedKey = Braccio.getKey(); }
+  }
+
+  if (pressedKey == BUTTON_SELECT)
+  {
+    // Fetch the joints positions
+    Braccio.positions(angles);
+
+    // Print the joint angles
+    Serial.println("************* Joints Angles *************");
+    Serial.println("|\tMotor ID\t|\tAngle\t|");
+    Serial.println("----------------------------------------");
+    Serial.print("| 1 - Gripper\t\t|\t" + String(angles[0]) + "\t|\n" + 
+                 "| 2 - Wrist Rotation\t|\t" + String(angles[1]) + "\t|\n" +
+                 "| 3 - Wrist Vertical\t|\t" + String(angles[2]) + "\t|\n" + 
+                 "| 4 - Elbow\t\t|\t" + String(angles[3]) + "\t|\n" + 
+                 "| 5 - Shoulder\t\t|\t" + String(angles[4]) + "\t|\n" + 
+                 "| 6 - Base\t\t|\t" + String(angles[5]) + "\t|\n" +
+                 "*****************************************\n\n\n\n\n");
+
+    while(pressedKey == BUTTON_SELECT) { pressedKey = Braccio.getKey(); }
+    
+  }
+}

examples/Platform_Tutorials/lessons/03-important-programming-concepts/Navigating_the_display_menu/Navigating_the_display_menu.ino

@@ -0,0 +1,81 @@
+#include <Braccio++.h>
+
+#define MARGIN_LEFT   0
+#define MARGIN_TOP    0
+
+// Arduino Colors
+#define COLOR_TEAL       0x00878F
+#define COLOR_LIGHT_TEAL 0x62AEB2
+#define COLOR_ORANGE     0xE47128
+#define COLOR_YELLOW     0xE5AD24
+#define COLOR_WHITE      0xFFFFFF
+
+static const char * btnm_map[] = {"Option 1", "Option 2", "\n",
+                                  "Option 3", "Option 4", "\n",
+                                  "Option 5", "Option 6", "\0"
+                                 };
+
+void setup() {
+  if (!Braccio.begin(customMenu)) {
+    if (Serial) Serial.println("Braccio.begin() failed.");
+    for(;;) { }
+  }
+}
+
+void loop() {
+  // Let here empty.
+}
+
+void customMenu(){
+  Braccio.lvgl_lock();
+
+  static lv_style_t style_bg;
+  lv_style_init(&style_bg);
+  lv_style_set_bg_color(&style_bg, lv_color_hex(COLOR_WHITE));
+
+  static lv_style_t style_btn;
+  lv_style_init(&style_btn);
+  lv_style_set_bg_color(&style_btn, lv_color_hex(COLOR_YELLOW));
+  lv_style_set_border_color(&style_btn, lv_color_hex(COLOR_LIGHT_TEAL));
+  lv_style_set_border_width(&style_btn, 2);
+  lv_style_set_text_color(&style_btn, lv_color_hex(COLOR_TEAL));
+  
+  
+  lv_obj_t * btnm = lv_btnmatrix_create(lv_scr_act());
+  lv_btnmatrix_set_map(btnm, btnm_map);
+  lv_obj_align(btnm, LV_ALIGN_CENTER, MARGIN_LEFT, MARGIN_TOP);
+  
+  lv_obj_add_style(btnm, &style_bg, 0);
+  lv_obj_add_style(btnm, &style_btn, LV_PART_ITEMS);
+
+  lv_btnmatrix_set_btn_ctrl(btnm, 0, LV_BTNMATRIX_CTRL_CHECKABLE);
+  lv_btnmatrix_set_btn_ctrl(btnm, 1, LV_BTNMATRIX_CTRL_CHECKABLE);
+  lv_btnmatrix_set_btn_ctrl(btnm, 2, LV_BTNMATRIX_CTRL_CHECKABLE);
+  lv_btnmatrix_set_btn_ctrl(btnm, 3, LV_BTNMATRIX_CTRL_CHECKABLE);
+  lv_btnmatrix_set_btn_ctrl(btnm, 4, LV_BTNMATRIX_CTRL_CHECKABLE);
+  lv_btnmatrix_set_btn_ctrl(btnm, 5, LV_BTNMATRIX_CTRL_CHECKABLE);
+
+  lv_btnmatrix_set_one_checked(btnm, true);
+  
+  lv_obj_add_event_cb(btnm, eventHandler, LV_EVENT_ALL, NULL);
+
+  Braccio.lvgl_unlock();
+
+  Braccio.connectJoystickTo(btnm);
+}
+
+static void eventHandler(lv_event_t * e){
+  Braccio.lvgl_lock();
+  
+  lv_event_code_t code = lv_event_get_code(e);
+  lv_obj_t * obj = lv_event_get_target(e);
+  if (code == LV_EVENT_CLICKED) {
+    uint32_t id = lv_btnmatrix_get_selected_btn(obj);
+    const char * txt = lv_btnmatrix_get_btn_text(obj, id);
+
+    LV_LOG_USER("%s was selected\n", txt);
+    Serial.println(String(txt) + " was selected.");
+  }
+  
+  Braccio.lvgl_unlock();
+}