[platform_view]add focus support for platform view

Author: hellohuanlin

shell/platform/darwin/ios/framework/Source/FlutterEngine.mm

@@ -986,6 +986,17 @@ - (void)flutterTextInputView:(FlutterTextInputView*)textInputView
                               arguments:@[ @(client) ]];
 }
 
+- (void)flutterTextInputViewDidResignFirstResponder:(FlutterTextInputView*)textInputView {
+  dispatch_async(dispatch_get_main_queue(), ^(void) {
+    long platform_view_id = self.platformViewsController->findFirstResponderPlatformViewId();
+    if (platform_view_id == -1) {
+      return;
+    }
+
+    [_platformViewsChannel.get() invokeMethod:@"viewFocused" arguments:@(platform_view_id)];
+  });
+}
+
 #pragma mark - Undo Manager Delegate
 
 - (void)flutterUndoManagerPlugin:(FlutterUndoManagerPlugin*)undoManagerPlugin

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews.mm

@@ -19,6 +19,20 @@
 #import "flutter/shell/platform/darwin/ios/ios_surface.h"
 #import "flutter/shell/platform/darwin/ios/ios_surface_gl.h"
 
+@implementation UIView (FirstResponder)
+- (BOOL)hasFirstResponderInViewHierarchy {
+  if (self.isFirstResponder) {
+    return YES;
+  }
+  for (UIView* subview in self.subviews) {
+    if (subview.hasFirstResponderInViewHierarchy) {
+      return YES;
+    }
+  }
+  return NO;
+}
+@end
+
 namespace flutter {
 
 std::shared_ptr<FlutterPlatformViewLayer> FlutterPlatformViewLayerPool::GetLayer(
@@ -328,6 +342,15 @@
   return [touch_interceptors_[view_id].get() embeddedView];
 }
 
+long FlutterPlatformViewsController::findFirstResponderPlatformViewId() {
+  for (auto const& [id, root_view] : root_views_) {
+    if ([(UIView*)root_view.get() hasFirstResponderInViewHierarchy]) {
+      return id;
+    }
+  }
+  return -1;
+}
+
 std::vector<SkCanvas*> FlutterPlatformViewsController::GetCurrentCanvases() {
   std::vector<SkCanvas*> canvases;
   for (size_t i = 0; i < composition_order_.size(); i++) {

shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsTest.mm

@@ -1105,4 +1105,36 @@ - (int)alphaOfPoint:(CGPoint)point onView:(UIView*)view {
   return pixel[3];
 }
 
+- (void)testHasFirstResponderInViewHierarchy_viewItselfBecomesFristResponder {
+  // For view to become the first responder, it must be a descendant of a UIWindow
+  UIWindow* window = [[UIWindow alloc] init];
+  UITextField* textField = [[UITextField alloc] init];
+  [window addSubview:textField];
+
+  [textField becomeFirstResponder];
+  XCTAssertTrue(textField.isFirstResponder);
+  XCTAssertTrue(textField.hasFirstResponderInViewHierarchy);
+  [textField resignFirstResponder];
+  XCTAssertFalse(textField.isFirstResponder);
+  XCTAssertFalse(textField.hasFirstResponderInViewHierarchy);
+}
+
+- (void)testHasFirstResponderInViewHierarchy_descendantViewBecomesFirstResponder {
+  // For view to become the first responder, it must be a descendant of a UIWindow
+  UIWindow* window = [[UIWindow alloc] init];
+  UIView* view = [[UIView alloc] init];
+  UIView* childView = [[UIView alloc] init];
+  UITextField* textField = [[UITextField alloc] init];
+  [window addSubview:view];
+  [view addSubview:childView];
+  [childView addSubview:textField];
+
+  [textField becomeFirstResponder];
+  XCTAssertTrue(textField.isFirstResponder);
+  XCTAssertTrue(view.hasFirstResponderInViewHierarchy);
+  [textField resignFirstResponder];
+  XCTAssertFalse(textField.isFirstResponder);
+  XCTAssertFalse(view.hasFirstResponderInViewHierarchy);
+}
+
 @end

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h

@@ -177,6 +177,10 @@ class FlutterPlatformViewsController {
 
   void OnMethodCall(FlutterMethodCall* call, FlutterResult& result);
 
+  // Returns the platform view id if the platform view (or any of its descendant view) is the first
+  // responder. Returns -1 if no such platform view found.
+  long findFirstResponderPlatformViewId();
+
  private:
   static const size_t kMaxLayerAllocations = 2;
 
@@ -329,4 +333,8 @@ class FlutterPlatformViewsController {
 - (UIView*)embeddedView;
 @end
 
+@interface UIView (FirstResponder)
+@property(nonatomic, readonly) BOOL hasFirstResponderInViewHierarchy;
+@end
+
 #endif  // FLUTTER_SHELL_PLATFORM_DARWIN_IOS_FRAMEWORK_SOURCE_FLUTTERPLATFORMVIEWS_INTERNAL_H_

shell/platform/darwin/ios/framework/Source/FlutterTextInputDelegate.h

@@ -59,6 +59,7 @@ typedef NS_ENUM(NSInteger, FlutterFloatingCursorDragState) {
     insertTextPlaceholderWithSize:(CGSize)size
                        withClient:(int)client;
 - (void)flutterTextInputView:(FlutterTextInputView*)textInputView removeTextPlaceholder:(int)client;
+- (void)flutterTextInputViewDidResignFirstResponder:(FlutterTextInputView*)textInputView;
 
 @end
 

shell/platform/darwin/ios/framework/Source/FlutterTextInputPlugin.mm

@@ -39,6 +39,7 @@
 static NSString* const kShowMethod = @"TextInput.show";
 static NSString* const kHideMethod = @"TextInput.hide";
 static NSString* const kSetClientMethod = @"TextInput.setClient";
+static NSString* const kSetPlatformViewClientMethod = @"TextInput.setPlatformViewClient";
 static NSString* const kSetEditingStateMethod = @"TextInput.setEditingState";
 static NSString* const kClearClientMethod = @"TextInput.clearClient";
 static NSString* const kSetEditableSizeAndTransformMethod =
@@ -1075,6 +1076,14 @@ - (BOOL)canBecomeFirstResponder {
   return _textInputClient != 0;
 }
 
+- (BOOL)resignFirstResponder {
+  BOOL success = [super resignFirstResponder];
+  if (success) {
+    [self.textInputDelegate flutterTextInputViewDidResignFirstResponder:self];
+  }
+  return success;
+}
+
 - (BOOL)canPerformAction:(SEL)action withSender:(id)sender {
   // When scribble is available, the FlutterTextInputView will display the native toolbar unless
   // these text editing actions are disabled.
@@ -2071,6 +2080,9 @@ - (void)handleMethodCall:(FlutterMethodCall*)call result:(FlutterResult)result {
   } else if ([method isEqualToString:kSetClientMethod]) {
     [self setTextInputClient:[args[0] intValue] withConfiguration:args[1]];
     result(nil);
+  } else if ([method isEqualToString:kSetPlatformViewClientMethod]) {
+    [self setPlatformViewTextInputClient:[args[@"platformViewId"] longValue]];
+    result(nil);
   } else if ([method isEqualToString:kSetEditingStateMethod]) {
     [self setTextInputEditingState:args];
     result(nil);
@@ -2187,6 +2199,13 @@ - (void)triggerAutofillSave:(BOOL)saveEntries {
   [self addToInputParentViewIfNeeded:_activeView];
 }
 
+- (void)setPlatformViewTextInputClient:(long)platformViewID {
+  [self removeEnableFlutterTextInputViewAccessibilityTimer];
+  _activeView.accessibilityEnabled = NO;
+  [_activeView removeFromSuperview];
+  [_inputHider removeFromSuperview];
+}
+
 - (void)setTextInputClient:(int)client withConfiguration:(NSDictionary*)configuration {
   [self resetAllClientIds];
   // Hide all input views from autofill, only make those in the new configuration visible