Add MacOS platform view support to FlutterViewController

Add platform view support in FlutterGLCompositor and FlutterViewController

Author: RichardJCai

ci/licenses_golden/licenses_flutter

@@ -1072,6 +1072,7 @@ FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterIOSur
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterIOSurfaceHolder.mm
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterMouseCursorPlugin.h
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterMouseCursorPlugin.mm
+FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterPlatformViews.h
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterResizeSynchronizer.h
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterResizeSynchronizer.mm
 FILE: ../../../flutter/shell/platform/darwin/macos/framework/Source/FlutterSurfaceManager.h

shell/platform/darwin/macos/BUILD.gn

@@ -62,6 +62,7 @@ source_set("flutter_framework_source") {
     "framework/Source/FlutterIOSurfaceHolder.mm",
     "framework/Source/FlutterMouseCursorPlugin.h",
     "framework/Source/FlutterMouseCursorPlugin.mm",
+    "framework/Source/FlutterPlatformViews.h",
     "framework/Source/FlutterResizeSynchronizer.h",
     "framework/Source/FlutterResizeSynchronizer.mm",
     "framework/Source/FlutterSurfaceManager.h",

shell/platform/darwin/macos/framework/Source/FlutterGLCompositor.h

@@ -5,6 +5,7 @@
 #include <map>
 
 #include "flutter/fml/macros.h"
+#include "flutter/shell/platform/darwin/macos/framework/Source/FlutterBackingStoreData.h"
 #include "flutter/shell/platform/darwin/macos/framework/Source/FlutterSurfaceManager.h"
 #include "flutter/shell/platform/darwin/macos/framework/Source/FlutterViewController_Internal.h"
 #include "flutter/shell/platform/embedder/embedder.h"
@@ -66,9 +67,17 @@ class FlutterGLCompositor {
   // created for the frame.
   bool frame_started_ = false;
 
+  // Update the backing CALayer using the backing store's specifications.
+  void PresentBackingStoreContent(
+      FlutterBackingStoreData* flutter_backing_store_data,
+      size_t layer_position);
+
   // Set frame_started_ to true and reset all layer state.
   void StartFrame();
 
+  // Remove platform views that are specified for deletion.
+  void DisposePlatformViews();
+
   // Creates a CALayer and adds it to ca_layer_map_ and increments
   // ca_layer_count_; Returns the key value (size_t) for the layer in
   // ca_layer_map_.

shell/platform/darwin/macos/framework/Source/FlutterGLCompositor.mm

@@ -71,35 +71,31 @@
 }
 
 bool FlutterGLCompositor::Present(const FlutterLayer** layers, size_t layers_count) {
+  DisposePlatformViews();
   for (size_t i = 0; i < layers_count; ++i) {
     const auto* layer = layers[i];
     FlutterBackingStore* backing_store = const_cast<FlutterBackingStore*>(layer->backing_store);
     switch (layer->type) {
       case kFlutterLayerContentTypeBackingStore: {
         if (backing_store->open_gl.framebuffer.user_data) {
-          FlutterBackingStoreData* backing_store_data =
+          FlutterBackingStoreData* flutter_backing_store_data =
               (__bridge FlutterBackingStoreData*)backing_store->open_gl.framebuffer.user_data;
-
-          FlutterIOSurfaceHolder* io_surface_holder = [backing_store_data ioSurfaceHolder];
-          size_t layer_id = [backing_store_data layerId];
-
-          CALayer* content_layer = ca_layer_map_[layer_id];
-
-          FML_CHECK(content_layer) << "Unable to find a content layer with layer id " << layer_id;
-
-          content_layer.frame = content_layer.superlayer.bounds;
-
-          // The surface is an OpenGL texture, which means it has origin in bottom left corner
-          // and needs to be flipped vertically
-          content_layer.transform = CATransform3DMakeScale(1, -1, 1);
-          IOSurfaceRef io_surface_contents = [io_surface_holder ioSurface];
-          [content_layer setContents:(__bridge id)io_surface_contents];
+          PresentBackingStoreContent(flutter_backing_store_data, i);
         }
         break;
       }
       case kFlutterLayerContentTypePlatformView:
-        // Add functionality in follow up PR.
-        FML_LOG(WARNING) << "Presenting PlatformViews not yet supported";
+        FML_CHECK([[NSThread currentThread] isMainThread])
+            << "Must be on the main thread to handle presenting platform views";
+        NSView* platform_view = view_controller_.platformViews[layer->platform_view->identifier];
+        CGFloat scale = [[NSScreen mainScreen] backingScaleFactor];
+        platform_view.frame = CGRectMake(layer->offset.x / scale, layer->offset.y / scale,
+                                         layer->size.width / scale, layer->size.height / scale);
+        if (platform_view.superview == nil) {
+          [view_controller_.flutterView addSubview:platform_view];
+        } else {
+          platform_view.layer.zPosition = i;
+        }
         break;
     };
   }
@@ -109,6 +105,29 @@
   return present_callback_();
 }
 
+void FlutterGLCompositor::PresentBackingStoreContent(
+    FlutterBackingStoreData* flutter_backing_store_data,
+    size_t layer_position) {
+  FML_CHECK([[NSThread currentThread] isMainThread])
+      << "Must be on the main thread to update CALayer contents";
+
+  FlutterIOSurfaceHolder* io_surface_holder = [flutter_backing_store_data ioSurfaceHolder];
+  size_t layer_id = [flutter_backing_store_data layerId];
+
+  CALayer* content_layer = ca_layer_map_[layer_id];
+
+  FML_CHECK(content_layer) << "Unable to find a content layer with layer id " << layer_id;
+
+  content_layer.frame = content_layer.superlayer.bounds;
+  content_layer.zPosition = layer_position;
+
+  // The surface is an OpenGL texture, which means it has origin in bottom left corner
+  // and needs to be flipped vertically
+  content_layer.transform = CATransform3DMakeScale(1, -1, 1);
+  IOSurfaceRef io_surface_contents = [io_surface_holder ioSurface];
+  [content_layer setContents:(__bridge id)io_surface_contents];
+}
+
 void FlutterGLCompositor::SetPresentCallback(
     const FlutterGLCompositor::PresentCallback& present_callback) {
   present_callback_ = present_callback;
@@ -139,4 +158,20 @@
   return ca_layer_count_++;
 }
 
+void FlutterGLCompositor::DisposePlatformViews() {
+  auto views_to_dispose = view_controller_.platformViewsToDispose;
+  if (views_to_dispose.empty()) {
+    return;
+  }
+
+  for (int64_t viewId : views_to_dispose) {
+    FML_CHECK([[NSThread currentThread] isMainThread])
+        << "Must be on the main thread to handle disposing platform views";
+    NSView* view = view_controller_.platformViews[viewId];
+    [view removeFromSuperview];
+    view_controller_.platformViews.erase(viewId);
+  }
+  views_to_dispose.clear();
+}
+
 }  // namespace flutter

shell/platform/darwin/macos/framework/Source/FlutterPlatformViews.h

@@ -0,0 +1,62 @@
+// Copyright 2013 The Flutter Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef FLUTTER_FLUTTERPLATFORMVIEWS_H_
+#define FLUTTER_FLUTTERPLATFORMVIEWS_H_
+
+#import <AppKit/AppKit.h>
+
+#import "FlutterCodecs.h"
+#import "FlutterMacros.h"
+
+NS_ASSUME_NONNULL_BEGIN
+
+/**
+ * Wraps a `NSView` for embedding in the Flutter hierarchy
+ */
+@protocol FlutterPlatformView <NSObject>
+/**
+ * Returns a reference to the `NSView` that is wrapped by this `FlutterPlatformView`.
+ *
+ * It is recommended to return a cached view instance in this method.
+ * Constructing and returning a new NSView instance in this method might cause undefined behavior.
+ *
+ * TODO(richardjcai): Prevent [FlutterPlatformView view] to be called multiple times
+ * in a single frame.
+ */
+- (NSView*)view;
+@end
+
+FLUTTER_EXPORT
+@protocol FlutterPlatformViewFactory <NSObject>
+/**
+ * Create a `FlutterPlatformView`.
+ *
+ * Implemented by MacOS code that expose a `FlutterPlatformView` for embedding in a Flutter app.
+ *
+ * The implementation of this method should create a new `FlutterPlatformView` and return it.
+ *
+ * @param frame The rectangle for the newly created `FlutterPlatformView` measured in points.
+ * @param viewId A unique identifier for this `FlutterPlatformView`.
+ * @param args Parameters for creating the `FlutterPlatformView` sent from the Dart side of the
+ * Flutter app. If `createArgsCodec` is not implemented, or if no creation arguments were sent from
+ * the Dart code, this will be null. Otherwise this will be the value sent from the Dart code as
+ * decoded by `createArgsCodec`.
+ */
+- (NSObject<FlutterPlatformView>*)createWithFrame:(CGRect)frame
+                                   viewIdentifier:(int64_t)viewId
+                                        arguments:(id _Nullable)args;
+
+/**
+ * Returns the `FlutterMessageCodec` for decoding the args parameter of `createWithFrame`.
+ *
+ * Only needs to be implemented if `createWithFrame` needs an arguments parameter.
+ */
+@optional
+- (NSObject<FlutterMessageCodec>*)createArgsCodec;
+@end
+
+NS_ASSUME_NONNULL_END
+
+#endif  // FLUTTER_FLUTTERPLATFORMVIEWS_H_

shell/platform/darwin/macos/framework/Source/FlutterViewController.mm

@@ -198,6 +198,9 @@ @implementation FlutterViewController {
 
   // A method channel for miscellaneous platform functionality.
   FlutterMethodChannel* _platformChannel;
+
+  // A method channel for platform view functionality.
+  FlutterMethodChannel* _platformViewsChannel;
 }
 
 @dynamic view;
@@ -211,6 +214,7 @@ static void CommonInit(FlutterViewController* controller) {
                                      allowHeadlessExecution:NO];
   controller->_additionalKeyResponders = [[NSMutableOrderedSet alloc] init];
   controller->_mouseTrackingMode = FlutterMouseTrackingModeInKeyWindow;
+  controller->_factories = [[NSMutableDictionary alloc] init];
 }
 
 - (instancetype)initWithCoder:(NSCoder*)coder {
@@ -377,10 +381,70 @@ - (void)addInternalPlugins {
       [FlutterMethodChannel methodChannelWithName:@"flutter/platform"
                                   binaryMessenger:_engine.binaryMessenger
                                             codec:[FlutterJSONMethodCodec sharedInstance]];
+
+  _platformViewsChannel =
+      [FlutterMethodChannel methodChannelWithName:@"flutter/platform_views"
+                                  binaryMessenger:_engine.binaryMessenger
+                                            codec:[FlutterStandardMethodCodec sharedInstance]];
+
   __weak FlutterViewController* weakSelf = self;
   [_platformChannel setMethodCallHandler:^(FlutterMethodCall* call, FlutterResult result) {
     [weakSelf handleMethodCall:call result:result];
   }];
+
+  [_platformViewsChannel setMethodCallHandler:^(FlutterMethodCall* call, FlutterResult result) {
+    [weakSelf handleMethodCall:call result:result];
+  }];
+}
+
+- (void)onCreate:(nonnull FlutterMethodCall*)call result:(nonnull FlutterResult)result {
+  NSMutableDictionary<NSString*, id>* args = [call arguments];
+  int64_t viewId = [args[@"id"] longValue];
+  NSString* viewType = [NSString stringWithUTF8String:([args[@"viewType"] UTF8String])];
+
+  if (_platformViews.count(viewId) != 0) {
+    result([FlutterError errorWithCode:@"recreating_view"
+                               message:@"trying to create an already created view"
+                               details:[NSString stringWithFormat:@"view id: '%lld'", viewId]]);
+  }
+
+  NSObject<FlutterPlatformViewFactory>* factory = _factories[viewType];
+  if (factory == nil) {
+    result([FlutterError errorWithCode:@"unregistered_view_type"
+                               message:@"trying to create a view with an unregistered type"
+                               details:[NSString stringWithFormat:@"unregistered view type: '%@'",
+                                                                  args[@"viewType"]]]);
+    return;
+  }
+
+  NSObject<FlutterPlatformView>* platform_view = [factory createWithFrame:CGRectZero
+                                                           viewIdentifier:viewId
+                                                                arguments:nil];
+
+  _platformViews[viewId] = [platform_view view];
+  result(nil);
+}
+
+- (void)onDispose:(nonnull FlutterMethodCall*)call result:(nonnull FlutterResult)result {
+  NSNumber* arg = [call arguments];
+  int64_t viewId = [arg longLongValue];
+  NSLog(@"onDispose ViewId: %lld", viewId);
+
+  if (_platformViews.count(viewId) == 0) {
+    result([FlutterError errorWithCode:@"unknown_view"
+                               message:@"trying to dispose an unknown"
+                               details:[NSString stringWithFormat:@"view id: '%lld'", viewId]]);
+    return;
+  }
+
+  // The following FlutterGLCompositor::Present call will dispose the views.
+  _platformViewsToDispose.insert(viewId);
+  result(nil);
+}
+
+- (void)registerViewFactory:(nonnull NSObject<FlutterPlatformViewFactory>*)factory
+                     withId:(nonnull NSString*)factoryId {
+  _factories[factoryId] = factory;
 }
 
 - (void)dispatchMouseEvent:(nonnull NSEvent*)event {
@@ -511,6 +575,10 @@ - (void)handleMethodCall:(FlutterMethodCall*)call result:(FlutterResult)result {
     result(nil);
   } else if ([call.method isEqualToString:@"Clipboard.hasStrings"]) {
     result(@{@"value" : @([self clipboardHasStrings])});
+  } else if ([[call method] isEqualToString:@"create"]) {
+    [self onCreate:call result:result];
+  } else if ([[call method] isEqualToString:@"dispose"]) {
+    [self onDispose:call result:result];
   } else {
     result(FlutterMethodNotImplemented);
   }

shell/platform/darwin/macos/framework/Source/FlutterViewController_Internal.h

@@ -2,20 +2,63 @@
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
-#import "flutter/shell/platform/darwin/macos/framework/Headers/FlutterViewController.h"
+#include <map>
+#include <unordered_set>
 
+#import "flutter/shell/platform/darwin/macos/framework/Headers/FlutterViewController.h"
+#import "flutter/shell/platform/darwin/macos/framework/Source/FlutterPlatformViews.h"
 #import "flutter/shell/platform/darwin/macos/framework/Source/FlutterView.h"
 
 @interface FlutterViewController ()
 
 // The FlutterView for this view controller.
 @property(nonatomic, readonly, nullable) FlutterView* flutterView;
 
+// NSDictionary maps strings to FlutterPlatformViewFactorys.
+@property(nonnull, nonatomic)
+    NSMutableDictionary<NSString*, NSObject<FlutterPlatformViewFactory>*>* factories;
+
+// A map of platform view ids to views.
+@property(nonatomic) std::map<int, NSView*> platformViews;
+
+// View ids that are going to be disposed on the next present call.
+@property(nonatomic) std::unordered_set<int64_t> platformViewsToDispose;
+
 /**
  * This just returns the NSPasteboard so that it can be mocked in the tests.
  */
 @property(nonatomic, readonly, nonnull) NSPasteboard* pasteboard;
 
+/**
+ * Platform View Methods.
+ */
+
+/**
+ * Creates a platform view using the arguments from the provided call.
+ * The call's arguments should be castable to an NSMutableDictionary<NSString*, id>*
+ * and the dictionary should at least hold one key for "id" that maps to the view id and
+ * one key for "viewType" which maps to the view type (string) that was used to register
+ * the factory.
+ * FlutterResult is updated to contain nil for success or to contain
+ * a FlutterError if there is an error.
+ */
+- (void)onCreate:(nonnull FlutterMethodCall*)call result:(nonnull FlutterResult)result;
+
+/**
+ * Disposes a platform view using the arguments from the provided call.
+ * The call's arguments should be the Id (castable to NSNumber*) of the platform view
+ * that should be disposed.
+ * FlutterResult is updated to contain nil for success or a FlutterError if there is an error.
+ */
+- (void)onDispose:(nonnull FlutterMethodCall*)call result:(nonnull FlutterResult)result;
+
+/**
+ * Register a view factory by adding an entry into the factories_ map with key factoryId
+ * and value factory.
+ */
+- (void)registerViewFactory:(nonnull NSObject<FlutterPlatformViewFactory>*)factory
+                     withId:(nonnull NSString*)factoryId;
+
 /**
  * Adds a responder for keyboard events. Key up and key down events are forwarded to all added
  * responders.