only clip when necessary

tests

fix tests

format

Author: Chris Yang

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews.mm

@@ -32,6 +32,16 @@ - (BOOL)flt_hasFirstResponderInViewHierarchySubtree {
 }
 @end
 
+static bool ClipBoundsContainsPlatformViewBoundingRect(const SkRect& clipBounds,
+                                                       const SkRect& platformViewBoundingRect,
+                                                       const SkMatrix& transformMatrix,
+                                                       CGFloat screenScale) {
+  SkRect transformedClipBounds = transformMatrix.mapRect(clipBounds);
+  SkMatrix reverseScreenScale = SkMatrix::Scale(1 / screenScale, 1 / screenScale);
+  SkRect scaledBoundingRect = reverseScreenScale.mapRect(platformViewBoundingRect);
+  return transformedClipBounds.contains(scaledBoundingRect);
+}
+
 namespace flutter {
 // Becomes NO if Apple's API changes and blurred backdrop filters cannot be applied.
 BOOL canApplyBlurBackdrop = YES;
@@ -404,7 +414,8 @@ - (BOOL)flt_hasFirstResponderInViewHierarchySubtree {
 }
 
 void FlutterPlatformViewsController::ApplyMutators(const MutatorsStack& mutators_stack,
-                                                   UIView* embedded_view) {
+                                                   UIView* embedded_view,
+                                                   const SkRect& bounding_rect) {
   if (flutter_view_ == nullptr) {
     return;
   }
@@ -418,7 +429,7 @@ - (BOOL)flt_hasFirstResponderInViewHierarchySubtree {
   // 500 points in UIKit. And until this point, we did all the calculation based on the flow
   // resolution. So we need to scale down to match UIKit's logical resolution.
   CGFloat screenScale = [UIScreen mainScreen].scale;
-  CATransform3D finalTransform = CATransform3DMakeScale(1 / screenScale, 1 / screenScale, 1);
+  SkMatrix transformMatrix = SkMatrix::Scale(1 / screenScale, 1 / screenScale);
 
   UIView* flutter_view = flutter_view_.get();
   FlutterClippingMaskView* maskView = [[[FlutterClippingMaskView alloc]
@@ -429,22 +440,41 @@ - (BOOL)flt_hasFirstResponderInViewHierarchySubtree {
   NSMutableArray* blurFilters = [[[NSMutableArray alloc] init] autorelease];
 
   auto iter = mutators_stack.Begin();
+  BOOL needMask = NO;
   while (iter != mutators_stack.End()) {
     switch ((*iter)->GetType()) {
       case kTransform: {
-        CATransform3D transform = GetCATransform3DFromSkMatrix((*iter)->GetMatrix());
-        finalTransform = CATransform3DConcat(transform, finalTransform);
+        transformMatrix = SkMatrix::Concat((*iter)->GetMatrix(), transformMatrix);
         break;
       }
-      case kClipRect:
-        [maskView clipRect:(*iter)->GetRect() matrix:finalTransform];
+      case kClipRect: {
+        if (ClipBoundsContainsPlatformViewBoundingRect((*iter)->GetRect(), bounding_rect,
+                                                       transformMatrix, screenScale)) {
+          break;
+        }
+        [maskView clipRect:(*iter)->GetRect() matrix:GetCATransform3DFromSkMatrix(transformMatrix)];
+        needMask = YES;
         break;
-      case kClipRRect:
-        [maskView clipRRect:(*iter)->GetRRect() matrix:finalTransform];
+      }
+      case kClipRRect: {
+        if (ClipBoundsContainsPlatformViewBoundingRect(
+                (*iter)->GetRRect().getBounds(), bounding_rect, transformMatrix, screenScale)) {
+          break;
+        }
+        [maskView clipRRect:(*iter)->GetRRect()
+                     matrix:GetCATransform3DFromSkMatrix(transformMatrix)];
+        needMask = YES;
         break;
-      case kClipPath:
-        [maskView clipPath:(*iter)->GetPath() matrix:finalTransform];
+      }
+      case kClipPath: {
+        if (ClipBoundsContainsPlatformViewBoundingRect(
+                (*iter)->GetPath().getBounds(), bounding_rect, transformMatrix, screenScale)) {
+          break;
+        }
+        [maskView clipPath:(*iter)->GetPath() matrix:GetCATransform3DFromSkMatrix(transformMatrix)];
+        needMask = YES;
         break;
+      }
       case kOpacity:
         embedded_view.alpha = (*iter)->GetAlphaFloat() * embedded_view.alpha;
         break;
@@ -498,8 +528,13 @@ - (BOOL)flt_hasFirstResponderInViewHierarchySubtree {
   // the mask view, whose origin is always (0,0) to the flutter_view.
   CATransform3D reverseTranslate =
       CATransform3DMakeTranslation(-clipView.frame.origin.x, -clipView.frame.origin.y, 0);
-  embedded_view.layer.transform = CATransform3DConcat(finalTransform, reverseTranslate);
-  clipView.maskView = maskView;
+  embedded_view.layer.transform =
+      CATransform3DConcat(GetCATransform3DFromSkMatrix(transformMatrix), reverseTranslate);
+  if (needMask) {
+    clipView.maskView = maskView;
+  } else {
+    clipView.maskView = nil;
+  }
 }
 
 void FlutterPlatformViewsController::CompositeWithParams(int view_id,
@@ -538,7 +573,7 @@ - (BOOL)flt_hasFirstResponderInViewHierarchySubtree {
   CGFloat screenScale = [UIScreen mainScreen].scale;
   clippingView.frame = CGRectMake(rect.x() / screenScale, rect.y() / screenScale,
                                   rect.width() / screenScale, rect.height() / screenScale);
-  ApplyMutators(mutatorStack, touchInterceptor);
+  ApplyMutators(mutatorStack, touchInterceptor, rect);
 }
 
 EmbedderPaintContext FlutterPlatformViewsController::CompositeEmbeddedView(int view_id) {

shell/platform/darwin/ios/framework/Source/FlutterPlatformViewsTest.mm

@@ -1478,6 +1478,74 @@ - (void)testChildClippingViewShouldBeTheBoundingRectOfPlatformView {
       kFloatCompareEpsilon);
 }
 
+- (void)testClipsDoNotInterceptWithPlatformViewShouldNotAddMaskView {
+  flutter::FlutterPlatformViewsTestMockPlatformViewDelegate mock_delegate;
+  auto thread_task_runner = CreateNewThread("FlutterPlatformViewsTest");
+  flutter::TaskRunners runners(/*label=*/self.name.UTF8String,
+                               /*platform=*/thread_task_runner,
+                               /*raster=*/thread_task_runner,
+                               /*ui=*/thread_task_runner,
+                               /*io=*/thread_task_runner);
+  auto flutterPlatformViewsController = std::make_shared<flutter::FlutterPlatformViewsController>();
+  auto platform_view = std::make_unique<flutter::PlatformViewIOS>(
+      /*delegate=*/mock_delegate,
+      /*rendering_api=*/flutter::IOSRenderingAPI::kSoftware,
+      /*platform_views_controller=*/flutterPlatformViewsController,
+      /*task_runners=*/runners);
+
+  FlutterPlatformViewsTestMockFlutterPlatformFactory* factory =
+      [[FlutterPlatformViewsTestMockFlutterPlatformFactory new] autorelease];
+  flutterPlatformViewsController->RegisterViewFactory(
+      factory, @"MockFlutterPlatformView",
+      FlutterPlatformViewGestureRecognizersBlockingPolicyEager);
+  FlutterResult result = ^(id result) {
+  };
+  flutterPlatformViewsController->OnMethodCall(
+      [FlutterMethodCall
+          methodCallWithMethodName:@"create"
+                         arguments:@{@"id" : @2, @"viewType" : @"MockFlutterPlatformView"}],
+      result);
+
+  XCTAssertNotNil(gMockPlatformView);
+
+  UIView* mockFlutterView = [[[UIView alloc] initWithFrame:CGRectMake(0, 0, 30, 30)] autorelease];
+  flutterPlatformViewsController->SetFlutterView(mockFlutterView);
+  // Create embedded view params
+  flutter::MutatorsStack stack;
+  // Layer tree always pushes a screen scale factor to the stack
+  SkMatrix screenScaleMatrix =
+      SkMatrix::Scale([UIScreen mainScreen].scale, [UIScreen mainScreen].scale);
+  stack.PushTransform(screenScaleMatrix);
+  SkMatrix translateMatrix = SkMatrix::Translate(5, 5);
+  // The platform view's rect for this test will be (5, 5, 10, 10)
+  stack.PushTransform(translateMatrix);
+  // Push a clip rect, big enough to contain the entire platform view bound
+  SkRect rect = SkRect::MakeXYWH(0, 0, 25, 25);
+  stack.PushClipRect(rect);
+  // Push a clip rrect, big enough to contain the entire platform view bound
+  SkRect rect_for_rrect = SkRect::MakeXYWH(0, 0, 24, 24);
+  SkRRect rrect = SkRRect::MakeRectXY(rect_for_rrect, 1, 1);
+  stack.PushClipRRect(rrect);
+  // Push a clip path, big enough to contain the entire platform view bound
+  SkPath path = SkPath::RRect(SkRect::MakeXYWH(0, 0, 23, 23), 1, 1);
+  stack.PushClipPath(path);
+
+  auto embeddedViewParams = std::make_unique<flutter::EmbeddedViewParams>(
+      SkMatrix::Concat(screenScaleMatrix, translateMatrix), SkSize::Make(5, 5), stack);
+
+  flutterPlatformViewsController->PrerollCompositeEmbeddedView(2, std::move(embeddedViewParams));
+  flutterPlatformViewsController->CompositeEmbeddedView(2);
+  gMockPlatformView.backgroundColor = UIColor.redColor;
+  XCTAssertTrue([gMockPlatformView.superview.superview isKindOfClass:ChildClippingView.class]);
+  ChildClippingView* childClippingView = (ChildClippingView*)gMockPlatformView.superview.superview;
+  [mockFlutterView addSubview:childClippingView];
+
+  [mockFlutterView setNeedsLayout];
+  [mockFlutterView layoutIfNeeded];
+
+  XCTAssertNil(childClippingView.maskView);
+}
+
 - (void)testClipRect {
   flutter::FlutterPlatformViewsTestMockPlatformViewDelegate mock_delegate;
   auto thread_task_runner = CreateNewThread("FlutterPlatformViewsTest");

shell/platform/darwin/ios/framework/Source/FlutterPlatformViews_Internal.h

@@ -280,7 +280,9 @@ class FlutterPlatformViewsController {
   // T_1 is applied to C_2, T_3 and T_4 are applied to C_5, and T_6 is applied to PLATFORM_VIEW.
   //
   // After each clip operation, we update the head to the super view of the current head.
-  void ApplyMutators(const MutatorsStack& mutators_stack, UIView* embedded_view);
+  void ApplyMutators(const MutatorsStack& mutators_stack,
+                     UIView* embedded_view,
+                     const SkRect& bounding_rect);
   void CompositeWithParams(int view_id, const EmbeddedViewParams& params);
 
   // Allocates a new FlutterPlatformViewLayer if needed, draws the pixels within the rect from