Group Grafana dashboard mounts into a single mapContainers (#671)

Currently, each `mapContainers` call adds an additional layer to the stack
When we get to a number of dashboards that is too high, this can go above the default max stack limit for jsonnet

Author: julienduchesne

grafana/configmaps.libsonnet

@@ -125,22 +125,24 @@ local configMap = k.core.v1.configMap;
   // Helper to mount a variable number of sharded config maps.
   local shardedMounts(folder) =
     local shards = calculateShards(folder);
-    std.foldl(
-      function(acc, shard)
-        acc + k.util.configVolumeMount(shard, '/grafana/%s/%s' % [prefix(folder.id), shard]),
-      std.objectFields(shards),
-      {}
-    ),
+    [
+      k.util.volumeMountItem(shard, '/grafana/%s/%s' % [prefix(folder.id), shard])
+      for shard in std.objectFields(shards)
+    ],
 
   // configmap mounts for use within statefulset/deployment
   configmap_mounts::
-    k.util.configMapVolumeMount($.grafana_ini_config_map, '/etc/grafana-config')
-    + k.util.configMapVolumeMount($.dashboard_provisioning_config_map, '%(provisioningDir)s/dashboards' % $._config)
-    + k.util.configMapVolumeMount($.grafana_datasource_config_map, '%(provisioningDir)s/datasources' % $._config)
-    + k.util.configMapVolumeMount($.notification_channel_config_map, '%(provisioningDir)s/notifiers' % $._config)
-    + std.foldr(
-      function(folder, acc) shardedMounts($.grafanaDashboardFolders[folder]) + acc,
-      std.objectFields($.grafanaDashboardFolders),
-      {},
-    ),
+    local mounts =
+      [
+        k.util.configMapVolumeMountItem($.grafana_ini_config_map, '/etc/grafana-config'),
+        k.util.configMapVolumeMountItem($.dashboard_provisioning_config_map, '%(provisioningDir)s/dashboards' % $._config),
+        k.util.configMapVolumeMountItem($.grafana_datasource_config_map, '%(provisioningDir)s/datasources' % $._config),
+        k.util.configMapVolumeMountItem($.notification_channel_config_map, '%(provisioningDir)s/notifiers' % $._config),
+      ]
+      + std.flattenArrays([
+        shardedMounts($.grafanaDashboardFolders[folder])
+        for folder in std.objectFields($.grafanaDashboardFolders)
+      ]);
+
+    k.util.volumeMounts(mounts),
 }

ksonnet-util/util.libsonnet

@@ -103,42 +103,55 @@ local util(k) = {
   // For example, passing "volumeMount.withSubPath(subpath)" will result in
   // a subpath mixin.
   configVolumeMount(name, path, volumeMountMixin={})::
-    local container = k.core.v1.container,
-          deployment = k.apps.v1.deployment,
-          volumeMount = k.core.v1.volumeMount,
-          volume = k.core.v1.volume,
-          addMount(c) = c + container.withVolumeMountsMixin(
-      volumeMount.new(name, path) +
-      volumeMountMixin,
-    );
-
-    deployment.mapContainers(addMount) +
-    deployment.mixin.spec.template.spec.withVolumesMixin([
-      volume.fromConfigMap(name, name),
-    ]),
+    $.volumeMounts([$.volumeMountItem(name, path, volumeMountMixin)]),
 
   // configMapVolumeMount adds a configMap to deployment-like objects.
   // It will also add an annotation hash to ensure the pods are re-deployed
   // when the config map changes.
   configMapVolumeMount(configMap, path, volumeMountMixin={})::
-    local name = configMap.metadata.name,
-          hash = std.md5(std.toString(configMap)),
-          container = k.core.v1.container,
+    $.volumeMounts([$.configMapVolumeMountItem(configMap, path, volumeMountMixin)]),
+
+
+  // configMapVolumeMountItem represents a config map to be mounted.
+  // It is used in the volumeMounts function
+  configMapVolumeMountItem(configMap, path, volumeMountMixin={})::
+    local name = configMap.metadata.name;
+    local annotations = { ['%s-hash' % name]: std.md5(std.toString(configMap)) };
+    $.volumeMountItem(name, path, volumeMountMixin, annotations),
+
+  // volumeMountItem represents a volume to be mounted.
+  // It is used in the volumeMounts function
+  volumeMountItem(name, path, volumeMountMixin={}, annotations={}):: {
+    name: name,
+    path: path,
+    volumeMountMixin: volumeMountMixin,
+    annotations: annotations,
+  },
+
+  // volumeMounts adds an array of volumeMountItem to deployment-like objects.
+  // It can also add a set of annotations for each mount
+  volumeMounts(mounts)::
+    local container = k.core.v1.container,
           deployment = k.apps.v1.deployment,
           volumeMount = k.core.v1.volumeMount,
-          volume = k.core.v1.volume,
-          addMount(c) = c + container.withVolumeMountsMixin(
-      volumeMount.new(name, path) +
-      volumeMountMixin,
+          volume = k.core.v1.volume;
+    local addMounts(c) = c + container.withVolumeMountsMixin([
+      volumeMount.new(m.name, m.path) +
+      m.volumeMountMixin
+      for m in mounts
+    ]);
+    local annotations = std.foldl(
+      function(acc, ann) acc + ann,
+      [m.annotations for m in mounts],
+      {}
     );
 
-    deployment.mapContainers(addMount) +
-    deployment.mixin.spec.template.spec.withVolumesMixin([
-      volume.fromConfigMap(name, name),
-    ]) +
-    deployment.mixin.spec.template.metadata.withAnnotationsMixin({
-      ['%s-hash' % name]: hash,
-    }),
+    deployment.mapContainers(addMounts)
+    + deployment.mixin.spec.template.spec.withVolumesMixin([
+      volume.fromConfigMap(m.name, m.name)
+      for m in mounts
+    ])
+    + (if annotations != {} then deployment.mixin.spec.template.metadata.withAnnotationsMixin(annotations) else {}),
 
   hostVolumeMount(name, hostPath, path, readOnly=false, volumeMountMixin={})::
     local container = k.core.v1.container,