Support for --project-file and --dist-dir flags.

These flags allow users to configure the location of
cabal.project and dist-newstyle, respectively.  Primary
motivation is for the test suite, to allow non-clobbering
inplace testing.

Bikeshed points:

- GlobalFlags or InstallFlags?  I picked GlobalFlags as it
  seemed more appropriate from a semantic perspective, but
  the downside is that you must now specify the flag
  before new-build, i.e., cabal --dist-dir=... new-build.
  However, if we ever support a Nix-style command that
  doesn't take the full complement of InstallFlags, GlobalFlags
  is the only place it could go.

- Flag names?  I think --project-file is good but perhaps
  someone has a better idea for --dist-dir.

- Is this in duplication with globalConfigFile?  I have
  no idea what that parameter does, so I don't think so.

It's not too easy to make the value of 'dist-dir' saveable
to the cabal.project file, as we'd prefer to load directly
from the cache if cabal.project is not updated.

Signed-off-by: Edward Z. Yang <[email protected]>

Author: ezyang

Cabal/doc/nix-local-build.rst

@@ -1697,5 +1697,35 @@ Most users generally won't need these.
     The command line variant of this field is
     ``--cabal-lib-version=1.24.0.1``.
 
+Top-level configuration flags
+-----------------------------
+
+These top-level flags must be passed before the subcommand (e.g.,
+``cabal --dist-dir=dist-newstyle.mine new-build``) and cannot be
+saved to the ``cabal.project`` file (as they affect how we find
+the ``cabal.project`` file and its cache.)
+
+.. option:: --project-file=FILE
+
+    Specifies the name of the project file used to specify the
+    rest of the top-level configuration; defaults to ``cabal.project``.
+    This name not only specifies the name of the main project file,
+    but also the auxiliary project files ``cabal.project.freeze``
+    and ``cabal.project.local``; for example, if you specify
+    ``--project-file=my.project``, then the other files that will
+    be probed are ``my.project.freeze`` and ``my.project.local``.
+
+    If the specified project file is a relative path, we will
+    look for the file relative to the current working directory,
+    and then for the parent directory, until the project file is
+    found or we have hit the top of the user's home directory.
+
+.. option:: --dist-dir=DIR
+
+    Specifies the name of the directory where build products for
+    build will be stored; defaults to ``dist-newstyle``.  If a
+    relative name is specified, this directory is resolved relative
+    to the root of the project (i.e., where the ``cabal.project``
+    file lives.)
 
 .. include:: references.inc

cabal-install/Distribution/Client/CmdConfigure.hs

@@ -31,9 +31,10 @@ configureCommand = Client.installCommand {
   commandUsage        = usageAlternatives "new-configure" [ "[FLAGS]" ],
   commandDescription  = Just $ \_ -> wrapText $
         "Configures a Nix-local build project, downloading source from"
-     ++ " the network and writing out a cabal.project.local file which"
-     ++ " saves any FLAGS, to be reapplied on subsequent invocations to "
-     ++ "new-build.",
+     ++ " the network and writing out a cabal.project.local file"
+     ++ " (or $project_file.local, if --project-file is specified)"
+     ++ " which saves any FLAGS, to be reapplied on subsequent invocations to"
+     ++ " new-build.",
   commandNotes        = Just $ \pname ->
         "Examples:\n"
      ++ "  " ++ pname ++ " new-configure           "
@@ -65,7 +66,7 @@ configureAction (configFlags, configExFlags, installFlags, haddockFlags)
           hookPrePlanning = \rootDir _ cliConfig ->
             -- Write out the @cabal.project.local@ so it gets picked up by the
             -- planning phase.
-            writeProjectLocalExtraConfig rootDir cliConfig,
+            writeProjectLocalExtraConfig globalFlags rootDir cliConfig,
 
           hookSelectPlanSubset = \buildSettings' elaboratedPlan -> do
             -- Select the same subset of targets as 'CmdBuild' would

cabal-install/Distribution/Client/CmdFreeze.hs

@@ -11,7 +11,7 @@ import Distribution.Client.ProjectPlanning
 import Distribution.Client.ProjectConfig
          ( ProjectConfig(..), ProjectConfigShared(..)
          , commandLineFlagsToProjectConfig, writeProjectLocalFreezeConfig
-         , findProjectRoot )
+         , findProjectRoot, getProjectFileName )
 import Distribution.Client.Targets
          ( UserConstraint(..) )
 import Distribution.Solver.Types.ConstraintSource
@@ -60,6 +60,7 @@ freezeCommand = Client.installCommand {
   commandDescription  = Just $ \_ -> wrapText $
         "Performs dependency solving on a Nix-local build project, and"
      ++ " then writes out the precise dependency configuration to cabal.project.freeze"
+     ++ " (or $project_file.freeze if --project-file is specified)"
      ++ " so that the plan is always used in subsequent builds.",
   commandNotes        = Just $ \pname ->
         "Examples:\n"
@@ -86,23 +87,23 @@ freezeAction (configFlags, configExFlags, installFlags, haddockFlags)
     cabalDir <- defaultCabalDir
     let cabalDirLayout = defaultCabalDirLayout cabalDir
 
-    projectRootDir <- findProjectRoot
-    let distDirLayout = defaultDistDirLayout projectRootDir
+    projectRootDir <- findProjectRoot globalFlags
+    let distDirLayout = defaultDistDirLayout globalFlags projectRootDir
 
     let cliConfig = commandLineFlagsToProjectConfig
                       globalFlags configFlags configExFlags
                       installFlags haddockFlags
 
 
     (_, elaboratedPlan, _, _) <-
-      rebuildInstallPlan verbosity
+      rebuildInstallPlan verbosity globalFlags
                          projectRootDir distDirLayout cabalDirLayout
                          cliConfig
 
     let freezeConfig = projectFreezeConfig elaboratedPlan
-    writeProjectLocalFreezeConfig projectRootDir freezeConfig
+    writeProjectLocalFreezeConfig globalFlags projectRootDir freezeConfig
     notice verbosity $
-      "Wrote freeze file: " ++ projectRootDir </> "cabal.project.freeze"
+      "Wrote freeze file: " ++ projectRootDir </> getProjectFileName globalFlags  <.> "freeze"
 
   where
     verbosity = fromFlagOrDefault normal (configVerbosity configFlags)

cabal-install/Distribution/Client/Config.hs

@@ -227,7 +227,9 @@ instance Semigroup SavedConfig where
         globalRequireSandbox    = combine globalRequireSandbox,
         globalIgnoreSandbox     = combine globalIgnoreSandbox,
         globalIgnoreExpiry      = combine globalIgnoreExpiry,
-        globalHttpTransport     = combine globalHttpTransport
+        globalHttpTransport     = combine globalHttpTransport,
+        globalDistDirName       = combine globalDistDirName,
+        globalProjectFileName   = combine globalProjectFileName
         }
         where
           combine        = combine'        savedGlobalFlags

cabal-install/Distribution/Client/DistDirLayout.hs

@@ -17,6 +17,8 @@ module Distribution.Client.DistDirLayout (
 ) where
 
 import System.FilePath
+import Distribution.Client.GlobalFlags
+import Distribution.Simple.Setup (fromFlagOrDefault)
 import Distribution.Package
          ( PackageId, ComponentId, UnitId )
 import Distribution.Compiler
@@ -106,12 +108,18 @@ data CabalDirLayout = CabalDirLayout {
        cabalWorldFile             :: FilePath
      }
 
-
-defaultDistDirLayout :: FilePath -> DistDirLayout
-defaultDistDirLayout projectRootDirectory =
+-- | Given the path to the dist directory (defaults to
+-- @$project_root/dist-newstyle@), create the 'DistDirLayout'
+-- associated with it.
+--
+-- NB: This used to accept just @project_root@, but to let the
+-- dist directory be configurable we changed it.
+defaultDistDirLayout :: GlobalFlags -> FilePath -> DistDirLayout
+defaultDistDirLayout globalFlags projectRootDirectory =
     DistDirLayout {..}
   where
-    distDirectory = projectRootDirectory </> "dist-newstyle"
+    distDirName = fromFlagOrDefault "dist-newstyle" (globalDistDirName globalFlags)
+    distDirectory = projectRootDirectory </> distDirName
     --TODO: switch to just dist at some point, or some other new name
 
     distBuildRootDirectory   = distDirectory </> "build"

cabal-install/Distribution/Client/GlobalFlags.hs

@@ -67,7 +67,19 @@ data GlobalFlags = GlobalFlags {
     globalRequireSandbox    :: Flag Bool,
     globalIgnoreSandbox     :: Flag Bool,
     globalIgnoreExpiry      :: Flag Bool,    -- ^ Ignore security expiry dates
-    globalHttpTransport     :: Flag String
+    globalHttpTransport     :: Flag String,
+    -- | Project-wide dist directory.  Defaults to @dist-newstyle@.
+    -- Assumed to be relative to the root of the project (as indicated
+    -- by @cabal.project@).
+    globalDistDirName       :: Flag FilePath,
+    -- | The cabal project file name; defaults to @cabal.project@.
+    -- Th name itself denotes the cabal project file name, but it also
+    -- is the base of auxiliary project files, such as
+    -- @cabal.project.local@ and @cabal.project.freeze@ which are also
+    -- read and written out in some cases.  If the path is not found
+    -- in the current working directory, we will successively probe
+    -- relative to parent directories until this name is found.
+    globalProjectFileName   :: Flag FilePath
   } deriving Generic
 
 defaultGlobalFlags :: GlobalFlags
@@ -85,7 +97,9 @@ defaultGlobalFlags  = GlobalFlags {
     globalRequireSandbox    = Flag False,
     globalIgnoreSandbox     = Flag False,
     globalIgnoreExpiry      = Flag False,
-    globalHttpTransport     = mempty
+    globalHttpTransport     = mempty,
+    globalDistDirName       = mempty,
+    globalProjectFileName   = mempty
   }
 
 instance Monoid GlobalFlags where

cabal-install/Distribution/Client/ProjectConfig.hs

@@ -37,6 +37,7 @@ module Distribution.Client.ProjectConfig (
     resolveSolverSettings,
     BuildTimeSettings(..),
     resolveBuildTimeSettings,
+    getProjectFileName,
 
     -- * Checking configuration
     checkBadPerPackageCompilerPaths,
@@ -46,6 +47,7 @@ module Distribution.Client.ProjectConfig (
 import Prelude ()
 import Distribution.Client.Compat.Prelude
 
+import Distribution.Client.GlobalFlags
 import Distribution.Client.ProjectConfig.Types
 import Distribution.Client.ProjectConfig.Legacy
 import Distribution.Client.RebuildMonad
@@ -55,8 +57,6 @@ import Distribution.Client.Glob
 import Distribution.Client.Types
 import Distribution.Client.DistDirLayout
          ( CabalDirLayout(..) )
-import Distribution.Client.GlobalFlags
-         ( RepoContext(..), withRepoContext' )
 import Distribution.Client.BuildReports.Types
          ( ReportLevel(..) )
 import Distribution.Client.Config
@@ -338,14 +338,20 @@ resolveBuildTimeSettings verbosity
 -- Reading and writing project config files
 --
 
+getProjectFileName :: GlobalFlags -> FilePath
+getProjectFileName globalFlags =
+    fromFlagOrDefault "cabal.project" (globalProjectFileName globalFlags)
+
 -- | Find the root of this project.
 --
 -- Searches for an explicit @cabal.project@ file, in the current directory or
 -- parent directories. If no project file is found then the current dir is the
 -- project root (and the project will use an implicit config).
 --
-findProjectRoot :: IO FilePath
-findProjectRoot = do
+findProjectRoot :: GlobalFlags -> IO FilePath
+findProjectRoot globalFlags = do
+
+    let projectFileName = getProjectFileName globalFlags
 
     curdir  <- getCurrentDirectory
     homedir <- getHomeDirectory
@@ -355,7 +361,7 @@ findProjectRoot = do
     let probe dir | isDrive dir || dir == homedir
                   = return curdir -- implicit project root
         probe dir = do
-          exists <- doesFileExist (dir </> "cabal.project")
+          exists <- doesFileExist (dir </> projectFileName)
           if exists
             then return dir       -- explicit project root
             else probe (takeDirectory dir)
@@ -367,20 +373,20 @@ findProjectRoot = do
 -- | Read all the config relevant for a project. This includes the project
 -- file if any, plus other global config.
 --
-readProjectConfig :: Verbosity -> FilePath -> Rebuild ProjectConfig
-readProjectConfig verbosity projectRootDir = do
-    global <- readGlobalConfig verbosity
-    local  <- readProjectLocalConfig       verbosity projectRootDir
-    freeze <- readProjectLocalFreezeConfig verbosity projectRootDir
-    extra  <- readProjectLocalExtraConfig  verbosity projectRootDir
+readProjectConfig :: Verbosity -> GlobalFlags -> FilePath -> Rebuild ProjectConfig
+readProjectConfig verbosity globalFlags projectRootDir = do
+    global <- readGlobalConfig             verbosity
+    local  <- readProjectLocalConfig       verbosity globalFlags projectRootDir
+    freeze <- readProjectLocalFreezeConfig verbosity globalFlags projectRootDir
+    extra  <- readProjectLocalExtraConfig  verbosity globalFlags projectRootDir
     return (global <> local <> freeze <> extra)
 
 
 -- | Reads an explicit @cabal.project@ file in the given project root dir,
 -- or returns the default project config for an implicitly defined project.
 --
-readProjectLocalConfig :: Verbosity -> FilePath -> Rebuild ProjectConfig
-readProjectLocalConfig verbosity projectRootDir = do
+readProjectLocalConfig :: Verbosity -> GlobalFlags -> FilePath -> Rebuild ProjectConfig
+readProjectLocalConfig verbosity globalFlags projectRootDir = do
   usesExplicitProjectRoot <- liftIO $ doesFileExist projectFile
   if usesExplicitProjectRoot
     then do
@@ -391,7 +397,7 @@ readProjectLocalConfig verbosity projectRootDir = do
       return defaultImplicitProjectConfig
 
   where
-    projectFile = projectRootDir </> "cabal.project"
+    projectFile = projectRootDir </> getProjectFileName globalFlags
     readProjectFile =
           reportParseResult verbosity "project file" projectFile
         . parseProjectConfig
@@ -419,25 +425,25 @@ readProjectLocalConfig verbosity projectRootDir = do
 -- or returns empty. This file gets written by @cabal configure@, or in
 -- principle can be edited manually or by other tools.
 --
-readProjectLocalExtraConfig :: Verbosity -> FilePath -> Rebuild ProjectConfig
-readProjectLocalExtraConfig verbosity =
-    readProjectExtensionFile verbosity "local"
+readProjectLocalExtraConfig :: Verbosity -> GlobalFlags -> FilePath -> Rebuild ProjectConfig
+readProjectLocalExtraConfig verbosity globalFlags =
+    readProjectExtensionFile verbosity globalFlags "local"
                              "project local configuration file"
 
 -- | Reads a @cabal.project.freeze@ file in the given project root dir,
 -- or returns empty. This file gets written by @cabal freeze@, or in
 -- principle can be edited manually or by other tools.
 --
-readProjectLocalFreezeConfig :: Verbosity -> FilePath -> Rebuild ProjectConfig
-readProjectLocalFreezeConfig verbosity =
-    readProjectExtensionFile verbosity "freeze"
+readProjectLocalFreezeConfig :: Verbosity -> GlobalFlags -> FilePath -> Rebuild ProjectConfig
+readProjectLocalFreezeConfig verbosity globalFlags =
+    readProjectExtensionFile verbosity globalFlags "freeze"
                              "project freeze file"
 
 -- | Reads a named config file in the given project root dir, or returns empty.
 --
-readProjectExtensionFile :: Verbosity -> String -> FilePath
+readProjectExtensionFile :: Verbosity -> GlobalFlags -> String -> FilePath
                          -> FilePath -> Rebuild ProjectConfig
-readProjectExtensionFile verbosity extensionName extensionDescription
+readProjectExtensionFile verbosity globalFlags extensionName extensionDescription
                          projectRootDir = do
     exists <- liftIO $ doesFileExist extensionFile
     if exists
@@ -446,7 +452,9 @@ readProjectExtensionFile verbosity extensionName extensionDescription
       else do monitorFiles [monitorNonExistentFile extensionFile]
               return mempty
   where
-    extensionFile = projectRootDir </> "cabal.project" <.> extensionName
+    extensionFile = projectRootDir </> projectFileName <.> extensionName
+
+    projectFileName = getProjectFileName globalFlags
 
     readExtensionFile =
           reportParseResult verbosity extensionDescription extensionFile
@@ -477,20 +485,20 @@ showProjectConfig =
 
 -- | Write a @cabal.project.local@ file in the given project root dir.
 --
-writeProjectLocalExtraConfig :: FilePath -> ProjectConfig -> IO ()
-writeProjectLocalExtraConfig projectRootDir =
+writeProjectLocalExtraConfig :: GlobalFlags -> FilePath -> ProjectConfig -> IO ()
+writeProjectLocalExtraConfig globalFlags projectRootDir =
     writeProjectConfigFile projectExtraConfigFile
   where
-    projectExtraConfigFile = projectRootDir </> "cabal.project.local"
+    projectExtraConfigFile = projectRootDir </> getProjectFileName globalFlags <.> "local"
 
 
 -- | Write a @cabal.project.freeze@ file in the given project root dir.
 --
-writeProjectLocalFreezeConfig :: FilePath -> ProjectConfig -> IO ()
-writeProjectLocalFreezeConfig projectRootDir =
+writeProjectLocalFreezeConfig :: GlobalFlags -> FilePath -> ProjectConfig -> IO ()
+writeProjectLocalFreezeConfig globalFlags projectRootDir =
     writeProjectConfigFile projectFreezeConfigFile
   where
-    projectFreezeConfigFile = projectRootDir </> "cabal.project.freeze"
+    projectFreezeConfigFile = projectRootDir </> getProjectFileName globalFlags <.> "freeze"
 
 
 -- | Write in the @cabal.project@ format to the given file.

cabal-install/Distribution/Client/ProjectConfig/Legacy.hs

@@ -472,7 +472,9 @@ convertToLegacySharedConfig
       globalRequireSandbox    = mempty,
       globalIgnoreSandbox     = mempty,
       globalIgnoreExpiry      = projectConfigIgnoreExpiry,
-      globalHttpTransport     = projectConfigHttpTransport
+      globalHttpTransport     = projectConfigHttpTransport,
+      globalProjectFileName   = mempty,
+      globalDistDirName       = mempty
     }
 
     configFlags = mempty {

cabal-install/Distribution/Client/ProjectOrchestration.hs

@@ -172,8 +172,8 @@ runProjectPreBuildPhase
     cabalDir <- defaultCabalDir
     let cabalDirLayout = defaultCabalDirLayout cabalDir
 
-    projectRootDir <- findProjectRoot
-    let distDirLayout = defaultDistDirLayout projectRootDir
+    projectRootDir <- findProjectRoot globalFlags
+    let distDirLayout = defaultDistDirLayout globalFlags projectRootDir
 
     let cliConfig = commandLineFlagsToProjectConfig
                       globalFlags configFlags configExFlags
@@ -189,7 +189,7 @@ runProjectPreBuildPhase
     -- the user has asked for.
     --
     (elaboratedPlan, _, elaboratedShared, projectConfig) <-
-      rebuildInstallPlan verbosity
+      rebuildInstallPlan verbosity globalFlags
                          projectRootDir distDirLayout cabalDirLayout
                          cliConfig