Add activation.hooks for pre-commit install

Author: roberth

default.nix

@@ -17,6 +17,7 @@ let
     ./modules/shell.nix
     ./modules/niv.nix
     ./modules/pre-commit.nix
+    ./modules/activation.nix
   ];
 
 in

modules/activation.nix

@@ -0,0 +1,62 @@
+{ config, lib, ... }:
+
+let
+
+  inherit (lib)
+    concatStringsSep
+    hasPrefix
+    literalExample
+    mkIf
+    mkOption
+    mkOptionType
+    mkOrder
+    types
+    ;
+
+  cfg = config.activation;
+
+  isOutsideStore = p: !(hasPrefix builtins.storeDir (toString p));
+
+in
+{
+  options = {
+
+    activation.hooks = mkOption {
+      type = types.listOf types.str;
+      description = ''
+        bash snippets to run on activation.
+
+        This is quite distinct from a shell hook:
+         - the working directory is always the project root.
+         - variables are not propagated to the shell.
+         - activation hooks may be run separately or before most shell.hooks.
+      '';
+      default = [];
+    };
+
+    activation.enableShellHook = mkOption {
+      type = types.bool;
+      description = ''
+        Whether to run the activation hooks whenever the project shell is opened.
+      '';
+      default = true;
+    };
+
+  };
+
+  config =
+    mkIf cfg.enableShellHook {
+
+      shell.extraAttrs.activationHook =
+        concatStringsSep "\n" cfg.hooks;
+
+      shell.hooks = mkIf (isOutsideStore config.root) (mkOrder 300 [''
+        (
+          echo 1>&2 project.nix: activating in ${lib.escapeShellArg config.root}
+          cd ${lib.escapeShellArg config.root}
+          runHook activationHook
+        )
+      '']);
+    };
+
+}

modules/pre-commit.nix

@@ -163,10 +163,9 @@ in
 
   config = mkIf cfg.enable {
 
-    # TODO: generalize the setup logic
-    # TODO: only autoinstall when in the project root
-    # TODO: always ignore when src is in the store
-    shell.hooks = mkIf cfg.enableAutoInstall [
+    shell.packages = [ cfg.package ];
+
+    activation.hooks = mkIf cfg.enableAutoInstall [
       ''
         export PATH=$PATH:${cfg.package}/bin
         if ! type -t git >/dev/null; then

modules/shell.nix

@@ -28,7 +28,15 @@ in
       example = [''if ! type git >/dev/null; then echo 1>&2 "git command not found! Please install git on your system or user profile"; fi''];
     };
 
-    # TODO environment variables
+    # TODO: can we specify merge functions in an extensible way?
+    extraAttrs = mkOption {
+      type = types.attrsOf types.str;
+      description = ''
+        Extra variables to set in the project's nix-shell.
+      '';
+      default = {};
+      example = { LANG = "en_US.UTF-8"; };
+    };
 
     shell = mkOption {
       type = types.package;
@@ -39,9 +47,9 @@ in
   };
 
   config = {
-    shell.shell = pkgs.mkShell {
+    shell.shell = pkgs.mkShell (cfg.extraAttrs // {
       nativeBuildInputs = cfg.packages;
       shellHook = lib.concatStringsSep "\n" cfg.hooks;
-    };
+    });
   };
 }