add some basic error handling, add update menu item mutation

Author: pascalstr

lib/plate_slate/menu/item.ex

@@ -22,5 +22,6 @@ defmodule PlateSlate.Menu.Item do
     |> cast(attrs, [:name, :description, :price, :added_on])
     |> validate_required([:name, :price])
     |> foreign_key_constraint(:category)
+    |> unique_constraint(:name)
   end
 end

lib/plate_slate_web/resolvers/menu.ex

@@ -1,16 +1,14 @@
+# ---
+# Excerpted from "Craft GraphQL APIs in Elixir with Absinthe",
+# published by The Pragmatic Bookshelf.
+# Copyrights apply to this code. It may not be used to create training material,
+# courses, books, articles, and the like. Contact us if you are in doubt.
+# We make no guarantees that this code is fit for any purpose.
+# Visit http://www.pragmaticprogrammer.com/titles/wwgraphql for more book information.
+# ---
 defmodule PlateSlateWeb.Resolvers.Menu do
   alias PlateSlate.Menu
 
-  def create_item(_, %{input: params}, _) do
-    case Menu.create_item(params) do
-      {:error, _} ->
-        {:error, "Could not create menu item"}
-
-      {:ok, _} = success ->
-        success
-    end
-  end
-
   def menu_items(_, args, _) do
     {:ok, Menu.list_items(args)}
   end
@@ -23,4 +21,42 @@ defmodule PlateSlateWeb.Resolvers.Menu do
     query = Ecto.assoc(category, :items)
     {:ok, PlateSlate.Repo.all(query)}
   end
+
+  def create_item(_, %{input: params}, _) do
+    case Menu.create_item(params) do
+      {:error, changeset} ->
+        {:ok, %{errors: transform_errors(changeset)}}
+
+      {:ok, menu_item} ->
+        {:ok, %{menu_item: menu_item}}
+    end
+  end
+
+  def update_item(_, %{id: id, input: input}, _) do
+    item = Menu.get_item!(id)
+
+    case Menu.update_item(item, input) do
+      {:error, changeset} ->
+        {:ok, %{errors: transform_errors(changeset)}}
+
+      {:ok, menu_item} ->
+        {:ok, %{menu_item: menu_item}}
+    end
+  end
+
+  defp transform_errors(changeset) do
+    changeset
+    |> Ecto.Changeset.traverse_errors(&format_error/1)
+    |> Enum.map(fn
+      {key, value} ->
+        %{key: key, message: value}
+    end)
+  end
+
+  @spec format_error(Ecto.Changeset.error()) :: String.t()
+  defp format_error({msg, opts}) do
+    Enum.reduce(opts, msg, fn {key, value}, acc ->
+      String.replace(acc, "%{#{key}}", to_string(value))
+    end)
+  end
 end

lib/plate_slate_web/schema.ex

@@ -1,17 +1,10 @@
 defmodule PlateSlateWeb.Schema do
   use Absinthe.Schema
 
-  alias PlateSlateWeb.Resolvers
-
   import_types(__MODULE__.MenuTypes)
 
   query do
     import_fields(:menu_queries)
-
-    field :search, list_of(:search_result) do
-      arg(:matching, non_null(:string))
-      resolve(&Resolvers.Menu.search/3)
-    end
   end
 
   mutation do
@@ -45,6 +38,12 @@ defmodule PlateSlateWeb.Schema do
     end)
   end
 
+  @desc "An error encountered trying to persist input"
+  object :input_error do
+    field :key, non_null(:string)
+    field :message, non_null(:string)
+  end
+
   enum :sort_order do
     value(:asc)
     value(:desc)

lib/plate_slate_web/schema/menu_types.ex

@@ -3,19 +3,35 @@ defmodule PlateSlateWeb.Schema.MenuTypes do
 
   alias PlateSlateWeb.Resolvers
 
+  object :menu_item_result do
+    field :menu_item, :menu_item
+    field :errors, list_of(:input_error)
+  end
+
   object :menu_queries do
     field :menu_items, list_of(:menu_item) do
       arg(:filter, :menu_item_filter)
       arg(:order, type: :sort_order, default_value: :asc)
       resolve(&Resolvers.Menu.menu_items/3)
     end
+
+    field :search, list_of(:search_result) do
+      arg(:matching, non_null(:string))
+      resolve(&Resolvers.Menu.search/3)
+    end
   end
 
   object :menu_mutations do
-    field :create_menu_item, :menu_item do
+    field :create_menu_item, :menu_item_result do
       arg(:input, non_null(:menu_item_input))
       resolve(&Resolvers.Menu.create_item/3)
     end
+
+    field :update_menu_item, :menu_item_result do
+      arg(:id, non_null(:id))
+      arg(:input, non_null(:update_item_input))
+      resolve(&Resolvers.Menu.update_item/3)
+    end
   end
 
   input_object :menu_item_input do
@@ -25,6 +41,13 @@ defmodule PlateSlateWeb.Schema.MenuTypes do
     field :category_id, non_null(:id)
   end
 
+  input_object :update_item_input do
+    field :name, :string
+    field :description, :string
+    field :price, :decimal
+    field :category_id, :id
+  end
+
   object :category do
     field(:name, :string)
     field(:description, :string)

priv/repo/migrations/20200513162215_add_index_for_menu_item_names.exs

@@ -0,0 +1,7 @@
+defmodule PlateSlate.Repo.Migrations.AddIndexForMenuItemNames do
+  use Ecto.Migration
+
+  def change do
+    create unique_index(:items, [:name])
+  end
+end

test/plate_slate_web/schema/mutation/create_menu_item_test.exs

@@ -1,3 +1,11 @@
+# ---
+# Excerpted from "Craft GraphQL APIs in Elixir with Absinthe",
+# published by The Pragmatic Bookshelf.
+# Copyrights apply to this code. It may not be used to create training material,
+# courses, books, articles, and the like. Contact us if you are in doubt.
+# We make no guarantees that this code is fit for any purpose.
+# Visit http://www.pragmaticprogrammer.com/titles/wwgraphql for more book information.
+# ---
 defmodule PlateSlateWeb.Schema.Mutation.CreateMenuTest do
   use PlateSlateWeb.ConnCase, async: true
 
@@ -19,13 +27,15 @@ defmodule PlateSlateWeb.Schema.Mutation.CreateMenuTest do
   @query """
   mutation ($menuItem: MenuItemInput!) {
     createMenuItem(input: $menuItem) {
-      name
-      description
-      price
+      errors { key message }
+      menuItem {
+        name
+        description
+        price
+      }
     }
   }
   """
-
   test "createMenuItem field creates an item", %{category_id: category_id} do
     menu_item = %{
       "name" => "French Dip",
@@ -44,9 +54,40 @@ defmodule PlateSlateWeb.Schema.Mutation.CreateMenuTest do
     assert json_response(conn, 200) == %{
              "data" => %{
                "createMenuItem" => %{
-                 "name" => menu_item["name"],
-                 "description" => menu_item["description"],
-                 "price" => menu_item["price"]
+                 "errors" => nil,
+                 "menuItem" => %{
+                   "name" => menu_item["name"],
+                   "description" => menu_item["description"],
+                   "price" => menu_item["price"]
+                 }
+               }
+             }
+           }
+  end
+
+  test "creating a menu item with an existing name fails",
+       %{category_id: category_id} do
+    menu_item = %{
+      "name" => "Reuben",
+      "description" => "Roast beef, caramelized onions, horseradish, ...",
+      "price" => "5.75",
+      "categoryId" => category_id
+    }
+
+    conn = build_conn()
+
+    conn =
+      post conn, "/api",
+        query: @query,
+        variables: %{"menuItem" => menu_item}
+
+    assert json_response(conn, 200) == %{
+             "data" => %{
+               "createMenuItem" => %{
+                 "errors" => [
+                   %{"key" => "name", "message" => "has already been taken"}
+                 ],
+                 "menuItem" => nil
                }
              }
            }