Require message body to be indented

Fix projectfluent#12, projectfluent#17, projectfluent#18.

With this change, the entire body of a message needs to indented. This makes
error recovery very easy: finding the next message definition is as simple as
finding the next identifier with no indentation.

It also opens up a number of opportunities: we can remove the `|` syntax for
multiline blocks of text and allow line breaks inside of placeables safely.

The PR also allows the value to be defined on a new line, making the
following examples equivalent:

    lipsum = Lorem ipsum dolor sit amet, consectetur adipiscing elit. Morbi
        pellentesque congue metus, non mattis sem faucibus sit amet.

    lipsum
        = Lorem ipsum dolor sit amet, consectetur adipiscing elit. Morbi
        pellentesque congue metus, non mattis sem faucibus sit amet.

I hope this will help when attributes are present:

    lipsum
        = Lorem ipsum dolor sit amet, consectetur adipiscing elit. Morbi
        pellentesque congue metus, non mattis sem faucibus sit amet.

        .attr = Attribute

Lastly, quoted patterns are only available inside of placeables and cannot be
used directly as values.

The exact semantics of \ escapes will be defined in projectfluent#22.

Author: stasm

syntax/fluent.ebnf

@@ -3,39 +3,42 @@ entry                ::= comment
                        | section
                        | message
 
-comment              ::= ('//' [^#xA#xD]* NL)+
-section              ::= '[[' __ word (__ word)* __ ']]'
+comment              ::= ('//' (char - NL)* NL)+
+section              ::= '[[' _ word (_ word)* _ ']]'
 
 char                 ::= [https://www.w3.org/TR/REC-xml/#NT-Char]
-__                   ::= [#x20#x9]*   /* space, tab */
-NL                   ::= [#xA#xD]+    /* line feed, carriage return */
+special              ::= [#x5b#x5c#x5d#x7b#x7d]   /* special chars: { } [ \ ] */
+line-break           ::= [#xA#xD]+    /* line feed, carriage return */
+inline-space         ::= [#x20#x9]+   /* space, tab */
+break-indent         ::= (line-break? inline-space)+
+
+_                    ::= inline-space
+NL                   ::= line-break
+__                   ::= break-indent
 
 identifier           ::= [a-zA-Z_?-] [a-zA-Z0-9_?-]*
 external             ::= '$' identifier
-word                 ::= [^#x20#x9#xA#xD#x5b#x5c#x5d]+   /* exclude: white space, [, \, ] */
+word                 ::= (((char - line-break) - inline-space) - special)+
 builtin              ::= [A-Z_?-]+
 number               ::= [0-9]+ ('.' [0-9]+)?
 
 variant-key          ::= number | variant-symbol
-variant-symbol       ::= word (__ word)*
-variant              ::= '[' variant-key ']' __ pattern NL
-default-variant      ::= '*' variant
-variant-list         ::= NL (__ variant)* __ default-variant (__ variant)*
-
-attribute            ::= '.' identifier __ '=' __ pattern NL
-attribute-list       ::= NL (__ attribute)+
-
-message              ::= identifier __ '=' __ (pattern attribute-list? | attribute-list)
-pattern              ::= unquoted-pattern
-                       | quoted-pattern
-unquoted-pattern     ::= (unquoted-text | placeable | block-text)+
-quoted-pattern       ::= '"' (quoted-text | placeable)* '"'
-unquoted-text        ::= ([^{] | '\{')+
-quoted-text          ::= ([^{"] | '\{' | '\"')+
-block-text           ::= NL __ '|' unquoted-pattern
+variant-symbol       ::= word (_ word)*
+variant              ::= NL __ '[' _ variant-key _ ']' __ pattern
+default-variant      ::= NL __ '*[' _ variant-key _ ']' __ pattern
+variant-list         ::= variant* default-variant variant*
+
+attribute            ::= NL __ '.' identifier __ value
+attribute-list       ::= attribute+
+
+message              ::= identifier (value attribute-list? | attribute-list)
+value                ::= __ '=' pattern
+pattern              ::= (text | placeable)+
+text                 ::= ((char - line-break) - special | break-indent | '\' special)+
+quoted-text          ::= '"' (text | '\"')+ '"'
 
 placeable            ::= '{' __ (expression | select-expression | variant-list) __ '}'
-expression           ::= quoted-pattern
+expression           ::= quoted-text
                        | number
                        | identifier
                        | external
@@ -44,10 +47,10 @@ expression           ::= quoted-pattern
                        | call-expression
                        | placeable
 
-select-expression    ::= expression __ ' ->' __ variant-list
+select-expression    ::= expression __ '->' __ variant-list
 attribute-expression ::= identifier '.' identifier
-variant-expression   ::= identifier '[' __ variant-key __ ']'
+variant-expression   ::= identifier '[' _ variant-key _ ']'
 call-expression      ::= builtin '(' __ (argument ( __ ',' __ argument)*)? __ ')'
 argument             ::= expression
                        | named-argument
-named-argument       ::= identifier __ ':' __ ('"' quoted-text? '"' | number)
+named-argument       ::= identifier __ ':' __ ('"' word? '"' | number)