chore: migrate from K/JVM to KMP (#244)

Part of #82.

Author: Vampire

.gitattributes

@@ -0,0 +1,3 @@
+*            text=auto
+*.bat        eol=crlf
+/gradlew     eol=lf

.gitignore

@@ -1,3 +1,4 @@
-.gradle
-.idea
-build
+/.gradle/
+/.idea/
+/.kotlin/
+/build/

build.gradle.kts

@@ -1,29 +1,54 @@
 plugins {
-    kotlin("jvm") version "2.1.0"
+    kotlin("multiplatform") version "2.1.0"
     kotlin("plugin.serialization") version "2.1.0"
-    application
+    id("io.kotest.multiplatform") version "5.9.1"
+    distribution
 }
 
-repositories {
-    mavenCentral()
-}
-
-dependencies {
-    implementation("com.charleskorn.kaml:kaml:0.67.0")
 
-    testImplementation(platform("io.kotest:kotest-bom:5.9.1"))
-    testImplementation("io.kotest:kotest-runner-junit5")
-    testImplementation("io.kotest:kotest-assertions-core")
-}
 
 kotlin {
     jvmToolchain(21)
-}
+    jvm {
+        mainRun {
+            mainClass = "it.krzeminski.githubactionstyping.MainKt"
+        }
+
+        val test by testRuns.existing {
+            executionTask {
+                useJUnitPlatform()
+            }
+        }
+    }
+
+    sourceSets {
+        jvmMain {
+            dependencies {
+                implementation("com.charleskorn.kaml:kaml:0.67.0")
+            }
+        }
 
-tasks.jar {
-    manifest.attributes["Main-Class"] = "MainKt"
+        jvmTest {
+            dependencies {
+                runtimeOnly("org.junit.platform:junit-platform-launcher")
+                implementation(dependencies.platform("io.kotest:kotest-bom:5.9.1"))
+                runtimeOnly("io.kotest:kotest-runner-junit5")
+                implementation("io.kotest:kotest-framework-api")
+                implementation("io.kotest:kotest-assertions-core")
+            }
+        }
+    }
 }
 
-tasks.withType<Test>().configureEach {
-    useJUnitPlatform()
+distributions {
+    main {
+        contents {
+            into("lib") {
+                val jvmJar by tasks.existing
+                from(jvmJar)
+                val jvmRuntimeClasspath by configurations
+                from(jvmRuntimeClasspath)
+            }
+        }
+    }
 }

settings.gradle.kts

@@ -1 +1,15 @@
+import org.gradle.api.initialization.resolve.RepositoriesMode.FAIL_ON_PROJECT_REPOS
+
+plugins {
+    id("org.gradle.toolchains.foojay-resolver-convention") version ("0.9.0")
+}
+
+dependencyResolutionManagement {
+    repositoriesMode = FAIL_ON_PROJECT_REPOS
+
+    repositories {
+        mavenCentral()
+    }
+}
+
 rootProject.name = "github-actions-typing"