Are Selector classes really unable to retrieve parent fields?

[afawcett]

Linked from old repo issue here, certinia/df12-apex-enterprise-patterns#6

[afawcett]

See original issue comment here, certinia/df12-apex-enterprise-patterns#6 (comment)

Having centralised SOQL Builders is of immensive use, but not being able to query parent fields limits its usage in enterprise apps very much

This doesn't even compile

    public List<Schema.SObjectField> getSObjectFieldList() {
        return new List<Schema.SObjectField> {
            ChildRecord__c.Name,
            ChildRecord__c.Parent__c,
            ChildRecord__c.Parent__r.GranParent__c
        };
}

This compiles but doesn't query the defined fields:

    public List<Schema.SObjectField> getSObjectFieldList() {
        return new List<Schema.SObjectField> {
            ChildRecord__c.Name,
            ChildRecord__c.Parent__r.Id,
            ChildRecord__c.Parent__r.GranParent__r.Id
        };
    }

[afawcett]

See original comment here, certinia/df12-apex-enterprise-patterns#6 (comment)

It's correct, the getSObjectFieldList method objective is list all fields from current SObject.

When you build your queries use getRelatedFieldListString('relationship_name'), to access parent fields, like this:

    String query = String.format(
        ' SELECT {0},{1}' + 
        ' FROM {2}' +
        ' WHERE Id IN :idSet' +
        ' ORDER BY {3}',
        new List<String>{
            getFieldListString(),
            setInvestSelector.getRelatedFieldListString('Parent__r'),
            getSObjectName(),               
            getOrderBy()                
        }
    );  

[afawcett]

Since we released the fflib_QueryFactor a couple of weeks ago, i've been working on an update to the above pattern for handling related fields in the query. While the above example will still work, we will also support the ability to use the Query Factory, as a preview here is the code i will updating in the sample app repo shortly...

public List<Opportunity> selectByIdWithProducts(Set<ID> idSet)
{
    fflib_QueryFactory opportunitiesQueryFactory = newQueryFactory();

    fflib_QueryFactory lineItemsQueryFactory = 
        new OpportunityLineItemsSelector().
            addQueryFactorySubselect(opportunitiesQueryFactory);

    new PricebookEntriesSelector().
        configureQueryFactoryFields(lineItemsQueryFactory, 'PricebookEntry');
    new ProductsSelector().
        configureQueryFactoryFields(lineItemsQueryFactory, 'PricebookEntry.Product2');
    new PricebooksSelector().
        configureQueryFactoryFields(lineItemsQueryFactory, 'PricebookEntry.Pricebook2');

    return (List<Opportunity>) Database.query(
        opportunitiesQueryFactory.setCondition('id in :idSet').toSOQL());
}