Bring v4.0.0 to the main branch

.github/workflows/linux.yml

@@ -3,7 +3,7 @@ name: Linux
 on: [push, pull_request]
 
 jobs:
-  gcc7:
+  gcc10:
     strategy:
       fail-fast: false
       matrix:
@@ -19,7 +19,7 @@ jobs:
     - name: Install Dependencies
       run: |
         sudo apt-get update
-        sudo apt-get install -yq libgtest-dev libboost-program-options-dev rapidjson-dev ninja-build
+        sudo apt-get install -yq libgtest-dev libboost-program-options-dev rapidjson-dev ninja-build gcc-10 g++-10
 
     - name: Build GTest
       run: |
@@ -34,6 +34,9 @@ jobs:
 
     - name: Configure CMake
       shell: pwsh
+      env:
+        CC: gcc-10
+        CXX: g++-10
       working-directory: build/
       run: |
         $cmakeBuildType = '${{ matrix.config }}'

.github/workflows/macos.yml

@@ -9,7 +9,7 @@ jobs:
       matrix:
         config: [Debug, Release]
 
-    runs-on: macos-latest
+    runs-on: macos-11
 
     steps:
     - uses: actions/checkout@v2

CMakeLists.txt

@@ -1,13 +1,10 @@
 # Copyright (c) Microsoft Corporation. All rights reserved.
 # Licensed under the MIT License.
 
-cmake_minimum_required(VERSION 3.8.2)
+cmake_minimum_required(VERSION 3.15)
 
-if(CMAKE_VERSION VERSION_GREATER_EQUAL "3.15")
-  # Enable CMAKE_MSVC_RUNTIME_LIBRARY on Windows.
-  set(MSVC_MATCH_VCPKG_TRIPLET ON)
-  cmake_policy(SET CMP0091 NEW)
-endif()
+# Enable CMAKE_MSVC_RUNTIME_LIBRARY on Windows: https://cmake.org/cmake/help/latest/policy/CMP0091.html
+cmake_policy(SET CMP0091 NEW)
 
 # Default to the last updated version from version.txt.
 file(TO_CMAKE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/version.txt" VERSION_FILE)
@@ -33,8 +30,6 @@ endif()
 
 project(cppgraphqlgen VERSION ${LATEST_VERSION})
 
-set(CMAKE_CXX_STANDARD 17)
-
 set(GRAPHQL_INSTALL_INCLUDE_DIR include CACHE PATH "Header file install directory")
 set(GRAPHQL_INSTALL_TOOLS_DIR bin CACHE PATH "schemagen install directory")
 set(GRAPHQL_INSTALL_CMAKE_DIR lib/cmake CACHE PATH "CMake config files install directory")
@@ -45,7 +40,7 @@ option(BUILD_SHARED_LIBS "Build shared libraries instead of static libs" OFF)
 if(VCPKG_TARGET_TRIPLET)
   message(STATUS "Using ${VCPKG_TARGET_TRIPLET} triplet with vcpkg")
 
-  if(MSVC AND MSVC_MATCH_VCPKG_TRIPLET)
+  if(MSVC)
     # Match the MSVC runtime if we're using VCPKG with static libraries.
     if(VCPKG_TARGET_TRIPLET MATCHES [[^.+-static$]])
       set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

cmake/CMakeLists.txt

@@ -1,7 +1,7 @@
 # Copyright (c) Microsoft Corporation. All rights reserved.
 # Licensed under the MIT License.
 
-cmake_minimum_required(VERSION 3.8.2)
+cmake_minimum_required(VERSION 3.15)
 
 # Enable version checks in find_package
 include(CMakePackageConfigHelpers)
@@ -11,3 +11,10 @@ install(FILES
     ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-config.cmake
     ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake
   DESTINATION ${GRAPHQL_INSTALL_CMAKE_DIR}/${PROJECT_NAME})
+
+install(FILES
+    ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-functions.cmake
+    ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-update-schema-files.cmake
+    ${CMAKE_CURRENT_SOURCE_DIR}/${PROJECT_NAME}-update-client-files.cmake
+  CONFIGURATIONS ${GRAPHQL_INSTALL_CONFIGURATIONS}
+  DESTINATION ${GRAPHQL_INSTALL_CMAKE_DIR}/${PROJECT_NAME})

cmake/cppgraphqlgen-config.cmake

@@ -5,7 +5,7 @@
 cppgraphqlgen
 -------------
 
-The following import targets are created
+The following import targets are created:
 
 ::
 
@@ -15,8 +15,20 @@ The following import targets are created
   cppgraphqlgen::graphqlintrospection
   cppgraphqlgen::graphqljson
   cppgraphqlgen::schemagen
+  cppgraphqlgen::clientgen
+
+The following functions are defined to help with code generation and build targets:
+
+::
+
+  update_graphql_schema_files
+  add_graphql_schema_target
+  add_graphql_schema_no_introspection_target
+  update_graphql_client_files
+  add_graphql_client_target
 #]=======================================================================]
 
 include(CMakeFindDependencyMacro)
 find_package(Threads REQUIRED)
 include("${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-targets.cmake")
+include("${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-functions.cmake")

cmake/cppgraphqlgen-functions.cmake

@@ -0,0 +1,107 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+get_filename_component(GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT
+  "${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-update-schema-files.cmake"
+  ABSOLUTE)
+
+get_filename_component(GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT
+  "${CMAKE_CURRENT_LIST_DIR}/cppgraphqlgen-update-client-files.cmake"
+  ABSOLUTE)
+
+function(update_graphql_schema_files SCHEMA_TARGET SCHEMA_GRAPHQL SCHEMA_PREFIX SCHEMA_NAMESPACE)
+  set_property(DIRECTORY APPEND
+    PROPERTY CMAKE_CONFIGURE_DEPENDS ${SCHEMA_TARGET}_schema_files)
+
+  # Collect optional arguments
+  set(ADDITIONAL_SCHEMAGEN_ARGS "")
+  if(ARGC GREATER 4)
+    math(EXPR LAST_ARG "${ARGC} - 1")
+    foreach(ARGN RANGE 4 ${LAST_ARG})
+      set(NEXT_ARG "${ARGV${ARGN}}")
+      list(APPEND ADDITIONAL_SCHEMAGEN_ARGS "${NEXT_ARG}")
+    endforeach()
+  endif()
+
+  add_custom_command(
+    OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_TARGET}_schema_files
+    COMMAND
+      ${CMAKE_COMMAND} "-DSCHEMA_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
+      "-DSCHEMA_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
+      "-DSCHEMAGEN_PROGRAM=$<TARGET_FILE:cppgraphqlgen::schemagen>"
+      "-DSCHEMA_TARGET=${SCHEMA_TARGET}" "-DSCHEMA_GRAPHQL=${SCHEMA_GRAPHQL}"
+      "-DSCHEMA_PREFIX=${SCHEMA_PREFIX}" "-DSCHEMA_NAMESPACE=${SCHEMA_NAMESPACE}"
+      "-DADDITIONAL_SCHEMAGEN_ARGS=${ADDITIONAL_SCHEMAGEN_ARGS}"
+      -P ${GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT}
+    DEPENDS ${SCHEMA_GRAPHQL} ${GRAPHQL_UPDATE_SCHEMA_FILES_SCRIPT} cppgraphqlgen::schemagen
+    COMMENT "Generating ${SCHEMA_TARGET} GraphQL schema"
+    VERBATIM)
+endfunction()
+
+function(add_graphql_schema_target SCHEMA_TARGET)
+  add_custom_target(${SCHEMA_TARGET}_update_schema ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_TARGET}_schema_files)
+
+  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_TARGET}_schema_files)
+    file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_TARGET}_schema_files SCHEMA_FILES)
+    add_library(${SCHEMA_TARGET}_schema STATIC ${SCHEMA_FILES})
+    add_dependencies(${SCHEMA_TARGET}_schema ${SCHEMA_TARGET}_update_schema)
+    target_include_directories(${SCHEMA_TARGET}_schema PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+    target_link_libraries(${SCHEMA_TARGET}_schema PUBLIC cppgraphqlgen::graphqlintrospection)
+  endif()
+endfunction()
+
+function(add_graphql_schema_no_introspection_target SCHEMA_NO_INTROSPECTION_TARGET)
+  add_custom_target(${SCHEMA_NO_INTROSPECTION_TARGET}_update_schema ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_NO_INTROSPECTION_TARGET}_schema_files)
+
+  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_NO_INTROSPECTION_TARGET}_schema_files)
+    file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/${SCHEMA_NO_INTROSPECTION_TARGET}_schema_files SCHEMA_FILES)
+    add_library(${SCHEMA_NO_INTROSPECTION_TARGET}_schema STATIC ${SCHEMA_FILES})
+    add_dependencies(${SCHEMA_NO_INTROSPECTION_TARGET}_schema ${SCHEMA_NO_INTROSPECTION_TARGET}_update_schema)
+    target_include_directories(${SCHEMA_NO_INTROSPECTION_TARGET}_schema PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+    target_link_libraries(${SCHEMA_NO_INTROSPECTION_TARGET}_schema PUBLIC cppgraphqlgen::graphqlservice)
+  endif()
+endfunction()
+
+function(update_graphql_client_files CLIENT_TARGET SCHEMA_GRAPHQL REQUEST_GRAPHQL CLIENT_PREFIX CLIENT_NAMESPACE)
+  set_property(DIRECTORY APPEND
+    PROPERTY CMAKE_CONFIGURE_DEPENDS ${CLIENT_TARGET}_client_files)
+
+  # Collect optional arguments
+  set(ADDITIONAL_CLIENTGEN_ARGS "")
+  if(ARGC GREATER 5)
+    math(EXPR LAST_ARG "${ARGC} - 1")
+    foreach(ARGN RANGE 5 ${LAST_ARG})
+      set(NEXT_ARG "${ARGV${ARGN}}")
+      list(APPEND ADDITIONAL_CLIENTGEN_ARGS "${NEXT_ARG}")
+    endforeach()
+  endif()
+
+  add_custom_command(
+    OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files
+    COMMAND
+      ${CMAKE_COMMAND} "-DCLIENT_SOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}"
+      "-DCLIENT_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}"
+      "-DCLIENTGEN_PROGRAM=$<TARGET_FILE:cppgraphqlgen::clientgen>" "-DCLIENT_TARGET=${CLIENT_TARGET}"
+      "-DSCHEMA_GRAPHQL=${SCHEMA_GRAPHQL}" "-DREQUEST_GRAPHQL=${REQUEST_GRAPHQL}"
+      "-DCLIENT_PREFIX=${CLIENT_PREFIX}" "-DCLIENT_NAMESPACE=${CLIENT_NAMESPACE}"
+      "-DADDITIONAL_CLIENTGEN_ARGS=${ADDITIONAL_CLIENTGEN_ARGS}"
+      -P ${GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT}
+    DEPENDS ${SCHEMA_GRAPHQL} ${REQUEST_GRAPHQL} ${GRAPHQL_UPDATE_CLIENT_FILES_SCRIPT} cppgraphqlgen::clientgen
+    COMMENT "Generating ${CLIENT_TARGET} client"
+    VERBATIM)
+endfunction()
+
+function(add_graphql_client_target CLIENT_TARGET)
+  add_custom_target(${CLIENT_TARGET}_update_client ALL
+    DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files)
+
+  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files)
+    file(STRINGS ${CMAKE_CURRENT_SOURCE_DIR}/${CLIENT_TARGET}_client_files CLIENT_FILES)
+    add_library(${CLIENT_TARGET}_client STATIC ${CLIENT_FILES})
+    add_dependencies(${CLIENT_TARGET}_client ${CLIENT_TARGET}_update_client)
+    target_include_directories(${CLIENT_TARGET}_client PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>)
+    target_link_libraries(${CLIENT_TARGET}_client PUBLIC cppgraphqlgen::graphqlclient)
+  endif()
+endfunction()

cmake/cppgraphqlgen-update-client-files.cmake

@@ -0,0 +1,60 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+# Normalize the filesystem paths
+get_filename_component(CLIENT_SOURCE_DIR ${CLIENT_SOURCE_DIR} ABSOLUTE)
+get_filename_component(CLIENT_BINARY_DIR ${CLIENT_BINARY_DIR} ABSOLUTE)
+get_filename_component(CLIENTGEN_PROGRAM ${CLIENTGEN_PROGRAM} ABSOLUTE)
+get_filename_component(SCHEMA_GRAPHQL "${CLIENT_SOURCE_DIR}/${SCHEMA_GRAPHQL}" ABSOLUTE)
+get_filename_component(REQUEST_GRAPHQL "${CLIENT_SOURCE_DIR}/${REQUEST_GRAPHQL}" ABSOLUTE)
+
+file(MAKE_DIRECTORY ${CLIENT_BINARY_DIR})
+
+# Cleanup all of the stale files in the binary directory
+file(GLOB PREVIOUS_FILES ${CLIENT_BINARY_DIR}/*.h ${CLIENT_BINARY_DIR}/*.cpp
+     ${CLIENT_BINARY_DIR}/${CLIENT_TARGET}_client_files)
+foreach(PREVIOUS_FILE ${PREVIOUS_FILES})
+  file(REMOVE ${PREVIOUS_FILE})
+endforeach()
+
+set(CLIENTGEN_ARGS "--schema=${SCHEMA_GRAPHQL}" "--request=${REQUEST_GRAPHQL}" "--prefix=${CLIENT_PREFIX}" "--namespace=${CLIENT_NAMESPACE}")
+foreach(CLIENTGEN_ARG ${ADDITIONAL_CLIENTGEN_ARGS})
+  list(APPEND CLIENTGEN_ARGS ${CLIENTGEN_ARG})
+endforeach()
+
+# Regenerate the sources in the binary directory
+execute_process(
+  COMMAND ${CLIENTGEN_PROGRAM} ${CLIENTGEN_ARGS}
+  OUTPUT_FILE ${CLIENT_TARGET}_client_files
+  WORKING_DIRECTORY ${CLIENT_BINARY_DIR})
+
+# Get the up-to-date list of files in the binary directory
+set(FILE_NAMES "")
+file(GLOB NEW_FILES ${CLIENT_BINARY_DIR}/*.h ${CLIENT_BINARY_DIR}/*.cpp)
+foreach(NEW_FILE ${NEW_FILES})
+  get_filename_component(NEW_FILE ${NEW_FILE} NAME)
+  list(APPEND FILE_NAMES "${NEW_FILE}")
+endforeach()
+
+# Don't update the files in the source directory if no files were generated in the binary directory.
+if(NOT FILE_NAMES)
+  message(FATAL_ERROR "Schema generation failed!")
+endif()
+
+ # Support if() IN_LIST operator: https://cmake.org/cmake/help/latest/policy/CMP0057.html
+cmake_policy(SET CMP0057 NEW)
+
+# Remove stale files in the source directory
+file(GLOB OLD_FILES ${CLIENT_SOURCE_DIR}/*.h ${CLIENT_SOURCE_DIR}/*.cpp)
+foreach(OLD_FILE ${OLD_FILES})
+  get_filename_component(OLD_FILE ${OLD_FILE} NAME)
+  if(NOT OLD_FILE IN_LIST FILE_NAMES)
+    file(REMOVE "${CLIENT_SOURCE_DIR}/${OLD_FILE}")
+  endif()
+endforeach()
+
+# Copy new and modified files from the binary directory to the source directory
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
+    ${CLIENT_BINARY_DIR}/${CLIENT_TARGET}_client_files
+    ${NEW_FILES}
+  ${CLIENT_SOURCE_DIR})

cmake/cppgraphqlgen-update-schema-files.cmake

@@ -0,0 +1,59 @@
+# Copyright (c) Microsoft Corporation. All rights reserved.
+# Licensed under the MIT License.
+
+# Normalize the filesystem paths
+get_filename_component(SCHEMA_SOURCE_DIR ${SCHEMA_SOURCE_DIR} ABSOLUTE)
+get_filename_component(SCHEMA_BINARY_DIR ${SCHEMA_BINARY_DIR} ABSOLUTE)
+get_filename_component(SCHEMAGEN_PROGRAM ${SCHEMAGEN_PROGRAM} ABSOLUTE)
+get_filename_component(SCHEMA_GRAPHQL "${SCHEMA_SOURCE_DIR}/${SCHEMA_GRAPHQL}" ABSOLUTE)
+
+file(MAKE_DIRECTORY ${SCHEMA_BINARY_DIR})
+
+# Cleanup all of the stale files in the binary directory
+file(GLOB PREVIOUS_FILES ${SCHEMA_BINARY_DIR}/*.h ${SCHEMA_BINARY_DIR}/*.cpp
+     ${SCHEMA_BINARY_DIR}/${SCHEMA_TARGET}_schema_files)
+foreach(PREVIOUS_FILE ${PREVIOUS_FILES})
+  file(REMOVE ${PREVIOUS_FILE})
+endforeach()
+
+set(SCHEMAGEN_ARGS "--schema=${SCHEMA_GRAPHQL}" "--prefix=${SCHEMA_PREFIX}" "--namespace=${SCHEMA_NAMESPACE}")
+foreach(SCHEMAGEN_ARG ${ADDITIONAL_SCHEMAGEN_ARGS})
+  list(APPEND SCHEMAGEN_ARGS ${SCHEMAGEN_ARG})
+endforeach()
+
+# Regenerate the sources in the binary directory
+execute_process(
+  COMMAND ${SCHEMAGEN_PROGRAM} ${SCHEMAGEN_ARGS}
+  OUTPUT_FILE ${SCHEMA_TARGET}_schema_files
+  WORKING_DIRECTORY ${SCHEMA_BINARY_DIR})
+
+# Get the up-to-date list of files in the binary directory
+set(FILE_NAMES "")
+file(GLOB NEW_FILES ${SCHEMA_BINARY_DIR}/*.h ${SCHEMA_BINARY_DIR}/*.cpp)
+foreach(NEW_FILE ${NEW_FILES})
+  get_filename_component(NEW_FILE ${NEW_FILE} NAME)
+  list(APPEND FILE_NAMES "${NEW_FILE}")
+endforeach()
+
+# Don't update the files in the source directory if no files were generated in the binary directory.
+if(NOT FILE_NAMES)
+  message(FATAL_ERROR "Schema generation failed!")
+endif()
+
+ # Support if() IN_LIST operator: https://cmake.org/cmake/help/latest/policy/CMP0057.html
+cmake_policy(SET CMP0057 NEW)
+
+# Remove stale files in the source directory
+file(GLOB OLD_FILES ${SCHEMA_SOURCE_DIR}/*.h ${SCHEMA_SOURCE_DIR}/*.cpp)
+foreach(OLD_FILE ${OLD_FILES})
+  get_filename_component(OLD_FILE ${OLD_FILE} NAME)
+  if(NOT OLD_FILE IN_LIST FILE_NAMES)
+    file(REMOVE "${SCHEMA_SOURCE_DIR}/${OLD_FILE}")
+  endif()
+endforeach()
+
+# Copy new and modified files from the binary directory to the source directory
+execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different
+    ${SCHEMA_BINARY_DIR}/${SCHEMA_TARGET}_schema_files
+    ${NEW_FILES}
+  ${SCHEMA_SOURCE_DIR})