feat(contracts): Add fee vault (#223)

Author: Thegaram

contracts/scripts/foundry/DeployL2BridgeContracts.s.sol

@@ -13,15 +13,20 @@ import { L2ERC721Gateway } from "../../src/L2/gateways/L2ERC721Gateway.sol";
 import { L2GatewayRouter } from "../../src/L2/gateways/L2GatewayRouter.sol";
 import { L2ScrollMessenger } from "../../src/L2/L2ScrollMessenger.sol";
 import { L2StandardERC20Gateway } from "../../src/L2/gateways/L2StandardERC20Gateway.sol";
+import { L2TxFeeVault } from "../../src/L2/predeploys/L2TxFeeVault.sol";
 import { Whitelist } from "../../src/L2/predeploys/Whitelist.sol";
 import { ScrollStandardERC20 } from "../../src/libraries/token/ScrollStandardERC20.sol";
 import { ScrollStandardERC20Factory } from "../../src/libraries/token/ScrollStandardERC20Factory.sol";
 
 contract DeployL2BridgeContracts is Script {
     uint256 L2_DEPLOYER_PRIVATE_KEY = vm.envUint("L2_DEPLOYER_PRIVATE_KEY");
+    address L1_TX_FEE_RECIPIENT_ADDR = vm.envAddress("L1_TX_FEE_RECIPIENT_ADDR");
+
+    L2ScrollMessenger messenger;
     ProxyAdmin proxyAdmin;
 
     address L2_SCROLL_MESSENGER_PREDEPLOY_ADDR = vm.envOr("L2_SCROLL_MESSENGER_PREDEPLOY_ADDR", address(0));
+    address L2_TX_FEE_VAULT_PREDEPLOY_ADDR = vm.envOr("L2_TX_FEE_VAULT_PREDEPLOY_ADDR", address(0));
     address L2_PROXY_ADMIN_PREDEPLOY_ADDR = vm.envOr("L2_PROXY_ADMIN_PREDEPLOY_ADDR", address(0));
     address L2_STANDARD_ERC20_GATEWAY_PROXY_PREDEPLOY_ADDR = vm.envOr("L2_STANDARD_ERC20_GATEWAY_PROXY_PREDEPLOY_ADDR", address(0));
     address L2_GATEWAY_ROUTER_PROXY_PREDEPLOY_ADDR = vm.envOr("L2_GATEWAY_ROUTER_PROXY_PREDEPLOY_ADDR", address(0));
@@ -35,6 +40,7 @@ contract DeployL2BridgeContracts is Script {
         vm.startBroadcast(L2_DEPLOYER_PRIVATE_KEY);
 
         deployL2ScrollMessenger();
+        deployTxFeeVault();
         deployProxyAdmin();
         deployL2StandardERC20Gateway();
         deployL2GatewayRouter();
@@ -54,9 +60,20 @@ contract DeployL2BridgeContracts is Script {
         }
 
         address owner = vm.addr(L2_DEPLOYER_PRIVATE_KEY);
-        L2ScrollMessenger l2ScrollMessenger = new L2ScrollMessenger(owner);
+        messenger = new L2ScrollMessenger(owner);
+
+        logAddress("L2_SCROLL_MESSENGER_ADDR", address(messenger));
+    }
+
+    function deployTxFeeVault() internal {
+        if (L2_TX_FEE_VAULT_PREDEPLOY_ADDR != address(0)) {
+            logAddress("L2_TX_FEE_VAULT_ADDR", address(L2_TX_FEE_VAULT_PREDEPLOY_ADDR));
+            return;
+        }
+
+        L2TxFeeVault feeVault = new L2TxFeeVault(address(messenger), L1_TX_FEE_RECIPIENT_ADDR);
 
-        logAddress("L2_SCROLL_MESSENGER_ADDR", address(l2ScrollMessenger));
+        logAddress("L2_TX_FEE_VAULT_ADDR", address(feeVault));
     }
 
     function deployProxyAdmin() internal {

contracts/scripts/foundry/InitializeL2BridgeContracts.s.sol

@@ -22,6 +22,7 @@ contract InitializeL2BridgeContracts is Script {
     address L1_ERC1155_GATEWAY_PROXY_ADDR = vm.envAddress("L1_ERC1155_GATEWAY_PROXY_ADDR");
 
     address L2_SCROLL_MESSENGER_ADDR = vm.envAddress("L2_SCROLL_MESSENGER_ADDR");
+    address L2_TX_FEE_VAULT_ADDR = vm.envAddress("L2_TX_FEE_VAULT_ADDR");
     address L2_STANDARD_ERC20_GATEWAY_PROXY_ADDR = vm.envAddress("L2_STANDARD_ERC20_GATEWAY_PROXY_ADDR");
     address L2_GATEWAY_ROUTER_PROXY_ADDR = vm.envAddress("L2_GATEWAY_ROUTER_PROXY_ADDR");
     address L2_SCROLL_STANDARD_ERC20_FACTORY_ADDR = vm.envAddress("L2_SCROLL_STANDARD_ERC20_FACTORY_ADDR");
@@ -74,12 +75,13 @@ contract InitializeL2BridgeContracts is Script {
 
         // whitelist contracts which can call sendMessage
         {
-            address[] memory gateways = new address[](5);
+            address[] memory gateways = new address[](6);
             gateways[0] = L2_STANDARD_ERC20_GATEWAY_PROXY_ADDR;
             gateways[1] = L2_GATEWAY_ROUTER_PROXY_ADDR;
             gateways[2] = L2_CUSTOM_ERC20_GATEWAY_PROXY_ADDR;
             gateways[3] = L2_ERC1155_GATEWAY_PROXY_ADDR;
             gateways[4] = L2_ERC721_GATEWAY_PROXY_ADDR;
+            gateways[5] = L2_TX_FEE_VAULT_ADDR;
             Whitelist(L2_WHITELIST_ADDR).updateWhitelistStatus(gateways, true);
         }
 

contracts/src/L2/predeploys/L2TxFeeVault.sol

@@ -0,0 +1,14 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity ^0.8.0;
+
+import { FeeVault } from "../../libraries/FeeVault.sol";
+
+/// @title L2TxFeeVault
+/// @notice The `L2TxFeeVault` contract collects all L2 transaction fees and allows withdrawing these fees to a predefined L1 address.
+/// The minimum withdrawal amount is 10 ether.
+contract L2TxFeeVault is FeeVault {
+  /// @param _messenger The address of L2ScrollMessenger.
+  /// @param _recipient The fee recipient address on L1.
+  constructor(address _messenger, address _recipient) FeeVault(_messenger, _recipient, 10 ether) {}
+}

contracts/src/libraries/FeeVault.sol

@@ -0,0 +1,108 @@
+// SPDX-License-Identifier: MIT
+
+// MIT License
+
+// Copyright (c) 2022 Optimism
+// Copyright (c) 2022 Scroll
+
+// Permission is hereby granted, free of charge, to any person obtaining a copy
+// of this software and associated documentation files (the "Software"), to deal
+// in the Software without restriction, including without limitation the rights
+// to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+// copies of the Software, and to permit persons to whom the Software is
+// furnished to do so, subject to the following conditions:
+
+// The above copyright notice and this permission notice shall be included in all
+// copies or substantial portions of the Software.
+
+// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+// IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+// FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+// AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+// LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+// OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+// SOFTWARE.
+
+pragma solidity ^0.8.0;
+
+import { IL2ScrollMessenger } from "../L2/IL2ScrollMessenger.sol";
+
+/**
+ * @title FeeVault
+ * @notice The FeeVault contract contains the basic logic for the various different vault contracts
+ *         used to hold fee revenue generated by the L2 system.
+ */
+abstract contract FeeVault {
+  /**
+   * @notice Emits each time that a withdrawal occurs.
+   *
+   * @param value Amount that was withdrawn (in wei).
+   * @param to    Address that the funds were sent to.
+   * @param from  Address that triggered the withdrawal.
+   */
+  event Withdrawal(uint256 value, address to, address from);
+
+  /**
+   * @notice Minimum balance before a withdrawal can be triggered.
+   */
+  uint256 public MIN_WITHDRAWAL_AMOUNT;
+
+  /**
+   * @notice Scroll L2 messenger address.
+   */
+  address public MESSENGER;
+
+  /**
+   * @notice Wallet that will receive the fees on L1.
+   */
+  address public RECIPIENT;
+
+  /**
+   * @notice Total amount of wei processed by the contract.
+   */
+  uint256 public totalProcessed;
+
+  /**
+   * @param _recipient           Wallet that will receive the fees on L1.
+   * @param _minWithdrawalAmount Minimum balance before a withdrawal can be triggered.
+   */
+  constructor(
+    address _messenger,
+    address _recipient,
+    uint256 _minWithdrawalAmount
+  ) {
+    MIN_WITHDRAWAL_AMOUNT = _minWithdrawalAmount;
+    MESSENGER = _messenger;
+    RECIPIENT = _recipient;
+  }
+
+  /**
+   * @notice Allow the contract to receive ETH.
+   */
+  receive() external payable {}
+
+  /**
+   * @notice Triggers a withdrawal of funds to the L1 fee wallet.
+   */
+  function withdraw() external {
+    uint256 value = address(this).balance;
+
+    require(
+      value >= MIN_WITHDRAWAL_AMOUNT,
+      "FeeVault: withdrawal amount must be greater than minimum withdrawal amount"
+    );
+
+    unchecked {
+      totalProcessed += value;
+    }
+
+    emit Withdrawal(value, RECIPIENT, msg.sender);
+
+    IL2ScrollMessenger(MESSENGER).sendMessage{ value: value }(
+      RECIPIENT,
+      0, // no fee provided
+      bytes(""), // no message (simple eth transfer)
+      0 // _gasLimit is not used for eth transfers
+    );
+  }
+}

contracts/src/test/L2TxFeeVault.t.sol

@@ -0,0 +1,43 @@
+// SPDX-License-Identifier: MIT
+
+pragma solidity ^0.8.0;
+
+import { DSTestPlus } from "solmate/test/utils/DSTestPlus.sol";
+
+import { MockScrollMessenger } from "./mocks/MockScrollMessenger.sol";
+import { L2TxFeeVault } from "../L2/predeploys/L2TxFeeVault.sol";
+
+contract L2TxFeeVaultTest is DSTestPlus {
+  MockScrollMessenger private messenger;
+  L2TxFeeVault private vault;
+
+  function setUp() public {
+    messenger = new MockScrollMessenger();
+    vault = new L2TxFeeVault(address(messenger), address(1));
+  }
+
+  function testCantWithdrawBelowMinimum() public {
+    hevm.deal(address(vault), 9 ether);
+    hevm.expectRevert("FeeVault: withdrawal amount must be greater than minimum withdrawal amount");
+    vault.withdraw();
+  }
+
+  function testWithdrawOnce() public {
+    hevm.deal(address(vault), 11 ether);
+    vault.withdraw();
+    assertEq(address(messenger).balance, 11 ether);
+    assertEq(vault.totalProcessed(), 11 ether);
+  }
+
+  function testWithdrawTwice() public {
+    hevm.deal(address(vault), 11 ether);
+    vault.withdraw();
+    assertEq(address(messenger).balance, 11 ether);
+    assertEq(vault.totalProcessed(), 11 ether);
+
+    hevm.deal(address(vault), 22 ether);
+    vault.withdraw();
+    assertEq(address(messenger).balance, 33 ether);
+    assertEq(vault.totalProcessed(), 33 ether);
+  }
+}